//<META NAME="robots" CONTENT="noindex">
// PoVRay 3.1 Scene File "flower1.pov"
// created by Friedrich A. Lohmüller,1998
#include "colors.inc"    
#include "textures.inc"
global_settings { assumed_gamma 1.8 }
// camera -----------------------------------------------------------
#declare Cam1 =camera {ultra_wide_angle angle 270 
                       //perspective angle 100
                       location  <0.0 , 2.0 , -5.3>
                       look_at   <-1.00 , 2.25 , -1.0>}
camera{Cam1}
// sun --------------------------------------------------------------
light_source{<1500,2500,-2500> color White}
// sky --------------------------------------------------------------
plane{<0,1,0>,1 hollow  //attention: hold sun lower than sky
       texture{pigment{Bright_Blue_Sky quick_color Blue 
                       scale 2.5 translate<8,0,8>}
	       finish {ambient 1 diffuse 0} }      
       scale 10000}

fog{fog_type   2
    distance  20
    color     rgb<0.95,1,0.9>
    fog_offset 0.1
    fog_alt    1.5
    turbulence 0.8}

// ground -----------------------------------------------------------
plane{<0,1,0>, 0 texture{ pigment{color YellowGreen}
                          normal {bumps 0.3 scale 0.05} 
                          finish {ambient 0.45 diffuse 0.55 phong 1}}}
//-------------------------------------------------------------------
#declare D = 0.0001;
//-------------------------------------------------------------------
#declare Z1 = seed(216);
#declare Z2 = seed(500);
//-------------------------------------------------------------------
#declare Kugel1 = 
 sphere{<0,0,0>,0.5 scale <1.75,1.2,0.8> 
        clipped_by{
        sphere{<0,0,0>,0.75 scale <1.5,1,0.3>  translate<0.25,0.25,0> }
        } 
        texture{pigment{color YellowGreen}
                normal {bumps 0.5 scale <0.5,0.05,0.03> } 
                finish {ambient 0.35 diffuse 0.55 phong 1}}
        translate<1,0,0>}
#declare Kranz1 =  
union{
#declare Nr = 0;     // Startwert
#declare EndNr = 20; // Endwert
#while (Nr< EndNr) 
   object{Kugel1 rotate<0,Nr * 360/EndNr,0>} 

 #declare Nr = Nr + 1;    // weiterzählen

#end // --------------- Schleifen-Ende 
translate<0,0,0>}


#declare Kugel2 = 
 sphere{<0,0,0>,0.65 scale <4.85,2.5,0.75>translate<1.95,0,0>
        clipped_by{
        sphere{<0,0,0>,0.75 scale <1.75,2.3,0.10>  translate<0.25,0.5,0> }
        }
        texture{pigment{color White}
                normal {bumps 0.5 scale <0.5,0.15,0.005> } 
                finish {ambient 0.35 diffuse 0.55 phong 1 reflection 0.2}}
        translate<1,0,0>}

#declare Kranz2 =  
union{
#declare Nr = 0;     // Startwert
#declare EndNr = 60; // Endwert
#while (Nr< EndNr) 
   object{Kugel2 rotate<2*(rand(Z1)-0.5),0,3*(rand(Z2)-0.5)> rotate<0,(Nr+0.5) * 360/EndNr,0>} 

 #declare Nr = Nr + 1;    // weiterzählen

#end // --------------- Schleifen-Ende 

translate<0,0,0>}    


#declare Kugel3 =  
union{
 cylinder {<0,0,0>,<0,2,0>,0.005 scale <1,1,1> rotate<0,0,0> translate<0,0,0> }
         // texture{pigment{color White}
         //         finish {ambient 0.45 diffuse 0.55 phong 1}}}
 sphere{<0,0,0>,0.02 scale <1,1,1> rotate<0,0,0> translate<0,2,0> }
        texture{pigment{color rgb<1,0.9,0>}
                normal {bumps 0.5 scale <0.5,0.05,0.03> } 
                finish {ambient 0.55 diffuse 0.55 phong 1}}
 rotate<0,0,0>
 translate<0,0,0>}

#declare Kranz3 =  
union{
#declare Nr = 0;     // Startwert
#declare EndNr = 120; // Endwert
#while (Nr< EndNr) 
   object{Kugel3 scale 1+0.1*(rand(Z2)-0.5) rotate<1*(rand(Z1)-0.5),0,-25+5*(rand(Z2)-0.5)> rotate<0,(Nr+0.5) * 360/EndNr,0>} 

 #declare Nr = Nr + 1;    // weiterzählen

#end // --------------- Schleifen-Ende 
translate<0,0,0>}    



union{
object{ Kranz1 translate<0,1.4,0>}    
object{ Kranz2 translate<0,1.0,0>}    
object{ Kranz3 translate<0,1.5,0>}    
scale 1.1
rotate<-50,25,0> translate<-1,0.7,0>}


union{
object{ Kranz1 translate<0,1.4,0>}    
object{ Kranz2 translate<0,1.0,0>}    
object{ Kranz3 translate<0,1.5,0>}    
scale 0.45
rotate<-40,-15,0> translate<0.8,0.4,-1.9>}


union{
object{ Kranz1 translate<0,1.4,0>}    
object{ Kranz2 translate<0,1.0,0>}    
object{ Kranz3 translate<0,1.5,0>}    
scale 0.45
rotate<-30,-35,0> translate<1.3,1.3,0.9>}