|
| "cylinder" = cilindro,
tubo, canna
|
|
|
cylinder = cilindro
Sintassi generale:
cylinder{ <x1,y1,z1>,<x2,y2,z2>, r
texture{ ... ... }
} |
Qui "<x1,y1,z1>"
e "<x2,y2,z2>"
sono le coordinate dei centri à le due fini e "r" è il raggio del cilindro.
|
Gli esempi qui:
// il cilindro bianco à sinistra:
cylinder{ <0,0,0>,<0,3,0>,1
texture{ pigment{ color White}
finish { reflection 0.1 phong 1}
}
scale <1,1,1> rotate<0,0,0> translate<0,0,0>
}
// le due cilindri viloletti in fronto:
cylinder{ <2,0,0>,<3.5,2,0>,0.2
texture{ pigment{ color Plum}
finish { phong 1}
}
scale <1,1,1> rotate<0,0,0> translate<0,0,-1>
}
cylinder{ <3.5,2,0>,<5,0,0>,0.2
texture{ pigment{ color Plum}
finish { phong 1}
}
scale <1,1,1> rotate<0,0,0> translate<0,0,-1>
}
// il disco di legna a destra:
cylinder {<0,0,0>,<0,0,0.5>,1
texture{ EMBWood1 scale 0.1
finish { phong 1}
}
translate<5,2,3>}
// il cilindro bianco sotile nel centro à destra:
cylinder{ <0,0,0>,<0,0.2,0>,2
texture{ pigment{ color White}
finish { reflection 0.1 phong 1}
}
scale <1,1,0.5> rotate<0,0,0> translate<4,0,2>
}
// il cilindro di cromo nel fondo:
cylinder{ <0,0,0>,<0,6,0>,2
texture{ Polished_Chrome
finish {reflection 0.7}
}
scale <1,1,1> rotate<0,0,0> translate<3,0,6>
} |
|
|
Consiglio: Per costruire un cilindro parallelo a una asse del sistema di coordinate ma non alla posizione zero,
questo è possibile in una maniera difficile, ma anche in una maniera più facile:
|
Lo stile per lo più molto cattivo è questo:
Punto di start e punto del fine del cilindro definito con valori definitivi
=> la lunghezza e la posizione è difficile da capire!
|
cylinder{ <4,2,2>,<4,2,5>,0.5
texture{ ... ... } } |
|
Lo stile più buono, più facile di capire è questo:
Principio di Costruzione:
Passo primo: modelare (lunghezza e raggio) il corpo a punto zero
e poi:
Passo secondo: muovere il corpo a la sua posizione finale.
In questo caso le istruzioni sono più facile da capire come segue:
|
cylinder{ <0,0,0>,<0,0,3>,0.5
translate<4,2,2>
texture{ ... ... } } |
|
|
Effeto speciale: Con la comando optional "open" abbiamo un cilindro aperto:
|
cylinder{ <0,0,0>, <0,0.35,0>, 0.45 open
texture { pigment{ color rgb<1,1,1>*0.75}
finish { phong 0.4 reflection 0.05}
} // end of texture
scale <1,1,1> rotate<0,0,0> translate<0,0,0>
} // end of cone ------------------------------ |
|
|
|
