Questo oggetto è definito con una macro nel mio
include file "shapes3.inc"
( precedentemente "shapes_lo.inc" ).
Egg, ovo
|
Egg_Shape, forma d'uovo
|
Sintassi generale:
object{ Egg
texture{ ... }
scale 1
rotate <0,0,0>
translate < 0, 0, 0>
} // end of object ---- |
|
Sintassi generale:
object{ Egg_Shape( Lower_Scale,
Upper_Scale
) //----------
texture{ ... ... }
} // end of object ------ |
Lower_Scale =
la scala y della parte inferiore e
Upper_Scale =
la scala y della parte superiore.
L'altezza totale di Questo oggetto è di 2 unità.
|
Example:
#include "shapes3.inc"
object{ Egg // = Egg_Shape(1.15,1.55)
texture{
pigment{ color rgb<1,1,1>}
normal { bumps 0.5 scale .002}
finish { phong 0.5 }
} // end of texture
rotate < 0, 0, 0>
translate < 0, 0, 0>
} // end of object -------------------- |
|
Example:
#include "shapes3.inc"
object{ Egg_Shape( 2.05, 0.65 )
texture{
pigment{ color rgb<1,1,1>}
normal { bumps 0.5 scale .002}
finish { phong 1 }
} // end of texture
rotate < 0, 0, 0>
translate < 0, 0, 0>
} // end of object --------------------- |
|
Qui qualche variazione di questa macro:
|
|
|
| "Egg object"
|
"Egg object"
|
La macro nel dettaglio
Questa macro è realizzato con una unione di due intersezioni d'ellissoidi
con parallelepipedi corrispondenti:
// -------------------------------------- macro Egg_Shape (...)
#macro Egg_Shape (Lower_Scale, Upper_Scale) //
// ------------------------------------------------------------
#local Egg_Lower_Part =
difference {
sphere{<0,0,0>,1 scale<1,Lower_Scale,1>}
box{<-1,0,-1>,<1,Lower_Scale,1>}
} //---------------------------------------
#local Egg_Upper_Part =
difference {
sphere {<0,0,0>,1 scale<1,Upper_Scale,1>}
box {<-1,-Upper_Scale,-1>,<1,0,1>}
}//---------------------------------------
//-------------------------------------------------------------
union {
object {Egg_Upper_Part}
object {Egg_Lower_Part}
translate<0,Lower_Scale,0>
scale 2/(Lower_Scale+Upper_Scale)
} // end of union -------------------------------------
#end //---------------------------------- end of the egg macro |
Questo oggetto Egg è realizzato con la stessa macro con le scale fisse: Lower_Scale = 1.15 e Upper_Scale = 1.55:
// ---------------------------- shape of a simple egg
#declare Egg = object { Egg_Shape (1.15,1.55)}
// ------------------------------------- end of the egg object |
|
|
