Accelerazione secondo
le formule de la fisica
Moto non-lineare in animazioni
per la simulazione di accelerazione ou decelerazione realistiche
secondo i leggi del moto dela fisica in POV-Ray.

I leggi del moto per movimenti semplici
// t = tempo, s = distanza, v = vcelocità, a = accelerazione )
1. Il moto rettilineo con velocità constante v:

Velocità	v = constante
Distanza percorsa	s(t) = v * t

//---------------------------------
#declare Total_Time = 4.48;
#declare Time = Total_Time*clock; //

#declare Time_A  = 2.65; // start with acceleration
#declare Time_B  = 3.45; //   end with acceleration
// total acceleration time:
#declare Ac_Time = Time_B-Time_A;
// last sector without acceleration:
#declare End_Time= Total_Time-Time_B;

#declare Acceleration =   5.0 ;
// v(0) = constant speed at start:
#declare V_0          =     1 ;

// final speed after acceleration
#declare End_Speed  = Acceleration * Ac_Time + V_0 ;

// covered distances
//1: with constant speed:
#declare Way1 = V_0*Time_A ;
//2: with constant acceleration
#declare Way2 =
   Acceleration/2*pow(Ac_Time,2)+V_0*Ac_Time+Way1;
   //note: pow(Ac_Time,2) = Ac_Time*Ac_Time

// with constant speed in last sector
//3: total distance
#declare Way3 =  End_Speed*(  End_Time ) + Way2 ;

//----------------------------

//---------------------------------
// calculating the distance at 'Time'
// covered by the rolling sphere;

 // constant translation
 #if ( Time < Time_A )
   #declare Way = V_0*Time;
 #end
 // constant translation + acceleration
 #if (( Time >= Time_A ) & ( Time < Time_B ))
   #declare Way = Acceleration/2*pow(Time - Time_A,2)
                  + V_0*(Time - Time_A) + Way1;
 #end
 // way with constant speed after acceleration ends
 #if ( Time >= Time_B )
   #declare Way = End_Speed*( Time - Time_B) + Way2;
 #end
//---------------------------------------------------
 sphere{<0,0,0>,0.75  translate<0,0.75, Way>}
 //--------------------------------------------------