Introduction au langage de description scènique POV-Ray raytracer         page 3
par Friedrich A. Lohmüller
EnglishEnglish English
Italiano Deutsch
Deutsch Deutsch

Page d'Accueil
- Tutoriels POV-Ray
 
  
Introduction POV-Ray
  Table des matières  -  INDEX
 
  1. Utiliser POV-Ray:
      "Insert Menu Add-on".
  2. Bases
      Comment écrire le texte
      xyz – Coordonnées,
      virgule flotante et vecteurs
>3. Structure d'une scène
      Exemple de base.
  4. La tête d'une scène
      Fichiers #include,
      camera, light_source.
  5. Objets géométriques de base
      sphere, box, cylinder,
      cone, torus, plane
      et autres formes
  6. Transformations
      échelle, rotation,
      translation et autres.
      CSG: union,
      difference, intersection.
  7. Couleurs et surfaces
      texture, pigment, normal, finish
  8. #declare, #local #macro.
      Variables, objets flexibles.
  9. #while - Boucles
      Exemples de base.,
 10. #include - fichiers include
      objets réutilisables.
 11. Efficacité,
      vitesse, flexibilité,
      travailer modulaire.
      Adapter de 3.1 à 3.5;3.6
      Adattare di 3.5;3.6 a 3.7
      POV-Ray + Windows Vista.
 
  - Insert Menu Add-on
    & Téléchargement
                                       
Ce qui appartient à une scène ?

Une description d'une scène doit contenir (au moins) les éléments suivants :

  • 0. #include Des fichiers à insérer avec des déclarations prédéfinies des couleurs, des textures et des choses semblables.
  • 1. camera = Cela définit le type de la caméra, la position de la caméra, le point de vue et l'angle visuel.
  • 2. light_source = définit la position et la couleur de la lumière.
  • 3. Les Objets géométrique et les propriétés de ces objets, en détail:
    • Formesphere, box, cylinder, cone, torus, plane « et beaucoup des autres!)
      Cette forme peut être un objet géométrique de base ou par ex.
      un composition des objets avec la méthode CSG = Constructive Solid Geometry.
    •   Transformations = des modifications de la position et de la forme
      •   'scale< , , >' - L'échelle - changer l'échelle
      •   'rotate< , , >' - Rotations autour du centre du système de coordonnées
      •   'translate< , , >' - Translations
    • 'texture' = La description de la consistance de la surface (» texture «)
      •   pigment{....} : La couleur (obligatoire!) et la transparence (optionnel, en cas échéant!)
      •   normal {.....} : La rugosité (optionnel, autrement un surface lisse!)
      •   finish {....} : La luminosité et la brillance du surface (on devrait utiliser!)

Un exemple de base pour une description de scène.

// POV-Ray 3.6/3.7 Scene File "Minimal.pov"
// by Friedrich A. Lohmueller, Jan-2013
//-------------------------------------------
#version 3.6; // 3.7
global_settings{assumed_gamma 1.0}
#default{ finish{ ambient 0.1 diffuse 0.9 }}
//------------------------------------------
#include "colors.inc"
#include "textures.inc"
//------------------------------------------
// camera ----------------------------------
camera{ location  <0.0 , 1.0 ,-3.0>
        look_at   <0.0 , 1.0 , 0.0>
        right x*image_width/image_height
        angle 75 }
// sun -------------------------------------
light_source{<1500,3000,-2500> color White}
// sky -------------------------------------
plane{ <0,1,0>,1 hollow
       texture{
         pigment{ bozo turbulence 0.92
           color_map{
                 [0.00 rgb<0.05,0.15,0.45>]
                 [0.50 rgb<0.05,0.15,0.45>]
                 [0.70 rgb<1,1,1>        ]
                 [0.85 rgb<0.2,0.2,0.2>  ]
                 [1.00 rgb<0.5,0.5,0.5>  ]
                       } //
           scale<1,1,1.5>*2.5
           translate<0,0,0>
           } // end of pigment
         finish {ambient 1 diffuse 0}
        } // end of texture
       scale 10000}
// fog on the ground -----------------------
fog { fog_type   2
      distance   50
      color      rgb<1,1,1>*0.8
      fog_offset 0.1
      fog_alt    1.5
      turbulence 1.8
    } //
// ground ----------------------------------
plane{ <0,1,0>, 0
       texture{
          pigment{ color rgb<0.22,0.45,0>}
          normal { bumps 0.75 scale 0.015 }
          finish { phong 0.1 }
       } // end of texture
     } // end of plane
//------------------------------------------
// objects in scene ------------------------
sphere{ <0,0,0>, 0.75
        translate<0.85,1.1,0>
        texture{
          pigment{ color rgb<0.9,0.55,0>}
          finish { phong 1 }
        } // end of texture
      } // end of sphere
//------------------------------------- end 
<- commentaires: version, titre, auteur, date

<- selection de la version
<- et evtl. correction de gamma

<- réglage (valeurs default)
<- illumination indirect / direct
<- Fichier include avec des couleurs
    et des textures predefinées


<- La position,
<- le point de vue
<- la proportion de l'image (aspect ratio)
<- l'angle de la caméra

<- » que la lumière soit! «

< Ici les objets de quoi
  ce monde est composé :

> le ciel...

> le sol ...

> un brouillard au sol

> ... et p.ex. une sphère
>  en couleur jaune chaude





Et ici le monde :

Description de cette scène pour POV-Ray :
Minimal.pov


part 0 | part 1 | part 2 | part 3 | part 4 | part 5 | part 6 | part 7 | part 8 | part 9 | part 10 | part 11

top

© Friedrich A. Lohmüller, 2014
homepage:www.f-lohmueller.de