Introduzione al linguaggio di descrizione di scene del raytracer POV-Ray        
di Friedrich A. Lohmüller
       Camera, Sorgenti di Luce e dettagli in POV-Ray
English English English
Français français
Deutsch Deutsch

Home
- POV-Ray Tutorials
 
  Camera + Luce
  
in POV-Ray
  Indice del contenuto
 
 Tipi di sorgenti di luce:
   puntiforme
   spotlight
   cylindrico,
   parallel,
   area_light, ombre diffuse
 
 Luce - le specialità:
   light_source visible
   shadowless
   projected_through
   Fading, attenuazione
 
 Tipi di Camera:
   perspective camera
   ultra_wide_angle
   orthographic camera
   cylindrical camera
   spherical camera
   fisheye camera
   panoramic camera
   omnimax camera
 
 Camera - le specialità:
   Aspect ratio
   Focal blur
   La camera perturbata

 Prospettiva architettonica
 
 Mostrare e nascondere:
   no_shadow
   no_reflection
   no_image
   no_body
 
                                             
Camera - le Specialità:
Aspect ratio:
Il rapporto tra altezza e larghezza dell'immagine

( aspect ratio = image_width / image_height )
La camera di POV-Ray è di default una camera 'perspective' che usa l'aspect ratio seguente:

camera{ location <0,1,-3>
        look_at  <0,1,0>
        up       <0,1,0>
        right <1.33,0,0> } 
I vettori up e right definiscono insieme il rapporto tra altezza e larghezza dell'immagine. Qui (default) abbiamo un aspect ratio de 4:3 (= 1.33/1).
L'aspect ratio di default 4:3 con immagine 4:3
Il 'problema aspect ratio':
Se cambiamo le proporzioni dell'immagine verso un immagine quadatica o un immagine di 16:9,
si può vedere distorsioni!

Perché queste distorsioni?


Con 1:1 abbiamo bisogno di
right <1,0,0>
e con 16:9 abbiamo bisogno di
right <16/9,0,0> !!!
L'aspect ratio di default 4:3
con un'immagine 1:1

L'aspect ratio di default 4:3
con un'immagine 16:9

La soluzione del 'problema aspect ratio':
Ci sono due variabili predefiniti nel POV-Ray per le dimensioni attualli
usato per l'immagine, chiamati
image_width e image_height:


camera{ location <0,1,-3>
        look_at  <0,1,0>
        right x*image_width/image_height
        }  // senza vettore 'right'! 
            (x = <1,0,0>)
Poi con questo 'aspect ratio automatico', otteniamo questo:
I distorsioni non ci sono più!
'aspect ratio automatico'
con un'immagine 1:1

'aspect ratio automatico'
con un'immagine 16:9


La Messa a Fuoco - 'focal blur'
Simulare la sfocatura e la profondità di campo di una fotografia con una camera reale.
camera{ angle 40
        location < 0.00,2.00,-3.00>
        look_at  < 0.00,2.00, 1.00>
        right  x*image_width/image_height      
     // focal blur settings:
        focal_point <0.20,1.5,-5.25>
        aperture 0.7     // 0.05 ~ 1.5
        blur_samples 100 // 4 ~ 100
        confidence 0.9   // 0 ~ 1
        variance 1/128   // 1/64 ~ 1/1024 ~
      } 
focal_point <0.20,1.5,-5.25> // Il punto focale, più nitida.
(Ho usato una piccola sfera rosso per trovare il punto corretto!)
aperture 0.7 // 0.05 ~ 1.5; // più = più sfocato
blur_samples 100 // 4 ~ 100, più = più alta qualità; meno = più veloce
confidence 0.9 // essere sufficientemente vicini al colore giusto, 0 ~ 1, default 0.9
variance 1/128 //(default) tolleranza accettabile sulla variazione
focal blur off
focal blur on

La camera perturbata
Usare l'istruzione 'normal' con la camera.
camera{ angle 40
        location < 0.00,2.00,-3.00>
        look_at  < 0.00,2.00, 1.00>
        right  x*image_width/image_height      
        normal{ bumps 0.15
                scale 0.4 translate<-0.2,0,0>}
      } 
....



camera{ angle 40
        location < 0.00,2.00,-3.00>
        look_at  < 0.00,2.00, 1.00>
        right  x*image_width/image_height      
        normal{ cells 0.15 turbulence 0.2
                scale 0.3 translate<-0.0,0,0>}
      } 
La camera perturbata con 'normal'+'bumps'
La camera perturbata con 'normal'+'cells'

Indice | Luce | Luce Specialità | Camera | Camera Specialità | Prospettiva architettonica | Mostrare + nascondere

top

© Friedrich A. Lohmüller, 2010
www.f-lohmueller.de