Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
Gestaltung des Inneren von transparenten Körpern in POV-Ray
English English English
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  Inhaltsübersicht
  material, interior, media

  - Syntax material
      texture + interior

  - Window Glass
      + max_trace_level
  - Nebel - fog
  Media
  - Syntax Media
  - Media + Density Maps
  Atmospheric Media
    mit/ohne density map
  - Lichtkegel im Nebel
  Object Media
  Emitting Media
  - Lichtschwert
  - Kerzenflammen
  Scattering Media
  - Licht durch Fenster
  - Dampf, Rauch, Wolken
  Absorbing Media
  - Staubteufel
  Spezialprobleme mit Media
  - Skalieren von Media
  - Überlappende Media
                                             

Staubteufel
mit Absorbing Media

Verwendung von "media absorption"
zur Simulation von Wirbelwinden wie Tornados oder Staubteufel.

Staubteufel mit media absorption.

Mit "media absorption" kann man Wirbelwinde simulieren. Das verwendete Container-Objekt (hier: eine Zylinderform) sollte klar durchsichtig sein und das Schlüsselwort hollow besitzen (dies erlaubt media- und fog-Effekte innerhalb!),
Das Container-Objekt wird zusammen mit der media-density skaliert. Letztere wird mit einer zusätzlichen density geformt.
Anmerkung: Die Farbe des absorbierten Lichts wird nach dem Schlüsselwort "absorption" spezifiziert. Aber "media" selbst und sein Schatten, beleuchtet von weissem Licht, hat die Farbe des nicht absorbierten Lichtes - dies bedeutet mit "media{ absorption <1,0,0> ...}" (absorbieren von Rot) die Farbe von "media" ist "<0,1,1>", dies ist die Farbe Cyan!


Beispiel "Staub-Teufel":
 // scattering media sample "dust devil"
 // -------------------------------------------------------
 cylinder{ <0,0,0>,<0,100,0>,1.5
           pigment { rgbt 1 }
           hollow

       interior{ //---------------------
          media{ scattering{ 1, <1,1,1>
                             extinction  2.5 }
                 absorption rgb< 0.61, 0.85, 0.85>*2
                 // density 1
                 density{ spiral2 10
                          turbulence 0.20
                          color_map {
                                [0.00 rgb 0.00] // border
                                [0.50 rgb 0.20] //
                                [1.00 rgb 1.00] // center
                              } // end color_map
                          rotate<90,0,0>
                          scale<1,0.5,1>
                        } // ----------- end of density 1
                 // density 2
                 density{ cylindrical
                          turbulence 1.0
                          frequency 1
                          color_map {
                                [0.00 rgb 0.00] // border
                                [0.50 rgb 0.20] //
                                [0.80 rgb 1.00] //
                                [1.00 rgb 0.50] // center
                              } // end color_map
                          scale<1,2,1>
                        } // ----------- end of density 2
          } // end of media ------------------
         } // ------------------ end of interior

  scale <1,1,1>
  rotate <0,0,-20>
  translate <0.00, 0.10, 0.00>
 }// end of object ----------------------------------------


"media" mit "absoprtion <1,0,0>" (rot)
ist sichtbar in "<0,1,1>" (cyan)!
"Staub-Teufel", realisiert mittels "media absorption".
Szenenbeschreibung für POV-Ray:
"absorbing_media_02.txt" oder "absorbing_media_02.pov"


Whirlwinds don't like to play solo!
top
© Friedrich A. Lohmüller, 2011
www.f-lohmueller.de