|
Avec "media absorption" nous pouvons simuler un tourbillon.
L'objet de conteneur utilisé (ici: une cylindre) être claire et avec le mot clè "hollow"
(Pour admettre les effets de média et de " fog " a l'intèrieur !).
La forme d'objet et la "density" du média peut être déformée par une "density" additionelle.
Note: Le couleur de la lumière "absorbée" est spécifiée après le mot clè " absorption ".
Mais le média même et son ombre, éclairée de lumière blanc, ont le couleur de la lumière non-absorbée !
C'est-à-dire :
avec "media{ absorption <1,0,0> ...}" (rouge absorbé)
le couleur de média est "<0,1,1>", c'est la couleur ;"cyan;"
Example "Trombe":
// example de scattering media "dust devil"
// -------------------------------------------------------
cylinder{ <0,0,0>,<0,100,0>,1.5
pigment { rgbt 1 }
hollow
interior{ //---------------------
media{ scattering{ 1, <1,1,1>
extinction 2.5 }
absorption rgb< 0.61, 0.85, 0.85>*2
// density 1
density{ spiral2 10
turbulence 0.20
color_map {
[0.00 rgb 0.00] // border
[0.50 rgb 0.20] //
[1.00 rgb 1.00] // center
} // end color_map
rotate<90,0,0>
scale<1,0.5,1>
} // ----------- end of density 1
// density 2
density{ cylindrical
turbulence 1.0
frequency 1
color_map {
[0.00 rgb 0.00] // border
[0.50 rgb 0.20] //
[0.80 rgb 1.00] //
[1.00 rgb 0.50] // center
} // end color_map
scale<1,2,1>
} // ----------- end of density 2
} // end of media ------------------
} // ------------------ end of interior
scale <1,1,1>
rotate <0,0,-20>
translate <0.00, 0.10, 0.00>
}// end of object ----------------------------------------
|
|
"media" avec "absoprtion <1,0,0>" (Red)
est visible en "<0,1,1>" (Cyan)!
|
