Home
- Tutorial POV-Ray
Immagini stereo e
Animazioni stereo
Index
Occhi incrociati
Immagini stereo semplici
Immagini stereo avanzate
Combinare immagini
> Animazioni stereo 1
Animazioni stereo 2
Esempi animazioni stereo
|
Animazioni stereo (1)
|
Come si fa
una serie d'immagini stereo per un'animazione.
1.1: Il file di scena stereo per POV-Ray
come indicato in Immagini Stereo avanzate.
Usiamo il 'frame_number' per controllare vista dell'occhio destro e sinistro:
numero di frame dispari 1, 3, 5, ... = vista dell'occhio destro,
numero di frame spari 2, 4, 6, ... = vista dell'occhio sinistro,
frame_number 0 = vista non-stereo per testare la scena.
per un'animazione di ad esempio 30 frames,
abbiamo bisogno
di rendere 2*30=60 frames!
Animazione con 'clock' e 'frame_number':
1. Animazione controllata dal 'frame_number':
Qui abbiamo bisogno di usare al interno un nuovo numero di frame,
chiamato 'Frame'.
Per numeri dispari di frame:
#declare Frame = int( frame_number/2 );
altro #declare Frame = int((frame_number+1)/2);
e come nuovo numero di frame finale:
#declare EndFrame = final_frame/2;
2. Animazione controllata dal 'clock':
Qui abbiamo bisogno di usare clock_delta
Per adattare il tempo internamente per i valori di clock!
(built-in clock_delta = differenza tra i valori di clock)
Per esempio: Con Initial_Clock=0, Final_Clock=1,
Initial_Frame=1 e Final_Frame=60,
usiamo per frame_number dispari:
#declare Time = clock ;
e per frame_number pari:
#declare Time = clock - clock_delta;
In un POV-Ray file di scena Stereo_Ani_00_.pov
si dichiara una telecamera stereo come segue:
(Per maggiori dettagli il file di scena adiacente !!! )
// -------------------- // stereo view:
#declare Stereo_On = 1;
#if( Stereo_On = 1 )
#declare Eye_Distance = 0.4;
// Numerazione dei frame:
// stereo starts: frame_number = 1
// odd frame numbers 1,3,5,... = right
// even frame number 2,4,6,... = left
// stereo: frame 1~60 -> frame pair = 1~30!
#if((frame_number/2)!=int(frame_number/2))
// odd frame_number
#declare Eye_Distance = -Eye_Distance;
#declare Time = clock ;
#declare Frame = (frame_number+1)/2 ;
#else // even frame_number
#declare Eye_Distance = Eye_Distance;
#declare Time = clock - clock_delta ;
#declare Frame = (frame_number )/2 ;
#end
#declare EndFrame = final_frame/2;
#else // Stereo_On = 0
#declare Eye_Distance = 0;
#declare Time = clock +0.0 ;
#declare Frame = frame_number ;
#declare EndFrame = final_frame ;
#end // of "#if( Stereo_On = 1 ) "
//------------------------------------------
#declare Camera_Position= < 0.0, 2.0,-4.0>;
#declare Camera_Look_At = < 0.0, 2.0, 0.0>;
#declare Camera_Angle = 65 ;
//------------------------------------------
camera{
location Camera_Position
+ Eye_Distance/2
* vnormalize(
vcross(
Camera_Look_At-Camera_Position,
<0,1,0>
)// vcross
)// vnormalize
right x*image_width/image_height
angle Camera_Angle
look_at Camera_Look_At
} // end camera
// .... lights and background ...
// .... and an object in scene:
object{
Wire_Box(<-1,-1,-1>,<1,1,1>,0.1,0)
texture{pigment{color rgb<1,1,1>*1.2}}
#if(frame_number != 0)// stereo
rotate<0, Time*90 ,0>
// or optional:
// rotate<0,(Frame-1)/EndFrame*90,0>
#end
translate<0,2.0,0>
} // --------------------------------------- |
Per un rendering quadratica, abbiamo messo in
riga di comando:
" +w240 +h240 ".
Con POV-Ray 3.7 è possibile utilizzare jpeg con
" +w240 +h240 +fj100 ".
|
La situazione di una telecamera in movimento libero:
non-stereo posizione della telecamera (viola),
posizioni occhio destro e sinistro (giallo/rosso),
punto 'look_at' mobile (giallo verde).
La scena non-stereo.
Resi con il file di scena. Senza runing su file ini,
Il frame_number di default è 0 !
Così il 'Half_Eye_Distance' è 0 e
rendering della scena mostra un immagine non-stereo.
|
1.2: Fare un file ini per l'animazione stereo
Nome di file: Stereo_Ani_00_.ini:
|
Antialias=On
Antialias_Threshold=0.3
Antialias_Depth=3
Input_File_Name=Stereo_Ani_00_.pov
Initial_Frame=1
Final_Frame=60
; 1~60 for 30 images
Initial_Clock=0
Final_Clock=1
Cyclic_Animation=on
Pause_when_Done=off |
Nota: frame_number 0 è riservato per la vista non-stereo!
L'esecuzione di questo file
fa una serie di 30 coppie di immagini stereo:
30 viste dell'occhio destro:
con numeri dispari 01,03,05,...,29
e 30 viste dell'occhio destro:
con numeri pari 02,04,06,...,30.
POV-Ray 3.6 / 3.7
file di scena stereo: Stereo_Ani_00_.pov
file ini stereo: Stereo_Ani_00_.ini
|
La vista dell'occhio destro.
Stereo_Ani_00_01.jpg
|
La vista dell'occhio sinistro.
Stereo_Ani_00_02.jpg
|
Continue with 2.1: Stereo Animation (2)
|
|
