Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
Gestaltung von Oberflächen mit POV-Ray -
English English English
Italiano Italiano
Français français

Home
- POV-Ray Tutorial
  Oberflächengestaltung
  - Farben und Texturen
    Inhalt

    texture Syntax
    - Grundbeispiel
    - pigment{ ... }
    - normal{ ... }
     > pigment_pattern
      - normal Beispiele
    - finish{ ... }
    Vorgefertigtes
    - Regeln
    - colors.inc
    - textures.inc
    Farben Do-it-Yourself
    - color rgb< , , >
    - Transparenz
    Muster
    Muster Listen
    Warps
    uv_mapping
    Mapping
    Überlagerungen

    Eigene Texturen
 
                                           
pigment_pattern

  Zur Syntax von "texture"

 'pigment_pattern' und 'normal'


Mit 'pigment_pattern' kann man jedes 'pigment' in Grautöne umwandeln.
Diese Grautöne kann man sowohl wieder für ein 'pigment' oder auch für ein 'normal'-Muster verwenden.
Es ergibt sich ein besonders interessanter Effekt, wenn man dasselbe Muster sowohl für
'normal{ pigment_pattern{ ... }, INTENSITY}'
als auch für 'pigment{...}' verwendet.

Benötigt man ein Muster in Grautönen von einem Bild, anstatt von einem Pigment, dann muss man 'image_map' oder 'material_map' verwenden.
Sintax for pigment, normal and texture:
pigment{
   pigment_pattern { PIGMENT_BODY }
   color_map { COLOR_MAP_BODY } |
   colour_map { COLOR_MAP_BODY } |
   pigment_map { PIGMENT_MAP_BODY }
 } //------------------------------
normal{
   pigment_pattern { PIGMENT_BODY }
                     [Bump_Size]
   normal_map { NORMAL_MAP_BODY }
 } //------------------------------
texture{
   pigment_pattern { PIGMENT_BODY }
   texture_map { TEXTURE_MAP_BODY }
 } //------------------------------

Beispiel: Zunächst deklariert man das Pigment
#declare Pigment_1 =
pigment{ gradient <0,1,0>  sine_wave
         color_map{
            [ 0.0 color rgb<1,1,1> ]
            [ 1.0 color rgb<1,0,0> ]
         } // end color_map
         scale 0.35
       } // end pigment
//---------------------------------------
sphere{ <0,0,0>, 0.75
        texture{
          pigment{ Pigment_1 }
          finish { phong 0.5 }
        } // end of texture --
        translate<-1,1,0>
      } // end of sphere left ----------
sphere{ <0,0,0>, 0.75
        texture{
            pigment{ pigment_pattern{ Pigment_1 }}
            finish { phong 0.5 }
        } // end of texture --
        translate<-1,1,0>
      } // end of sphere right ---------
Sample pigment_pattern
Kugel mit 'pigment' (links) und
mit 'pigment' aus pigment_pattern (rechts)
Beispiel: 'pigment_pattern' für 'normal'
sphere{ <0,0,0>, 0.75
        texture{
          pigment{ color rgb<1,1,1>}
          normal {pigment_pattern{Pigment_1},0.5}
          finish { phong 0.5  }
        } // end of texture
        translate<-1,1,0>
      } // end of sphere left ----------
sphere{ <0,0,0>, 0.75
        texture{
          pigment{  Pigment_1 }
          normal {pigment_pattern{Pigment_1},1.0}
          finish { phong 0.5 }
        } // end of texture --
        translate<-1,1,0>
      } // end of sphere right ---------
Sample pigment_pattern
Links: Weiße Kugel mit
normal aus pigment_pattern.
Rechts: Kugel mit 'pigment' und 'normal' mit 'pigment_pattern' aus demselben 'pigment'.
Mehr Beispiele zu 'pigment_pattern' finden sich hier:
pigment_pattern (1) u. pigment_pattern (2).

top

© Friedrich A. Lohmüller, 2012
www.f-lohmueller.de