Descriptions and Examples for the POV-Ray Raytracer by Friedrich A. Lohmüller
Design of Surfaces by "texture" with POV-Ray -
Deutsch Deutsch
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  Design of Surfaces
  - Colors and Textures
    Index

    texture Syntax
    Ready-made Textures
    Do-it-yourself Colors
    Patterns
    - pattern types
     Regular patterns
   > checker, hexagon,
      square, triangular
    - brick
    - object pattern (1)
    - object pattern (2)
    - object pattern (3)
    - tiling
    - pavement
     Stripe patterns
    - color_map{...}
      Patterns by pigments
    - pigment_pattern (1)
    - pigment_pattern (2)
    Patterns Lists
    - Regular Patterns
    - Random Patterns
    - Fractal Patterns
    - Other Patterns
    Warps
    - warp mapping
    uv_mapping
    Mapping
    Superpositions

    Your own Textures
 
                                           

Regular Patterns:
   checker, hexagon, square, triangular


checker
(original field lenght and width: 1 unit)
Example:
pigment{ checker // 2 colors/textures
         color White
         color Black }    


hexagon
Example:
pigment{ hexagon // 3 colors/textures
         color Red
         color Yellow
         color Orange }   


square
New in POV-Ray 3.7
(original field lenght and width: 1 unit)
Example::
pigment{ square //max.4 colors/textures
         color White
         color rgb<1.00, 0.00, 0.30>,
         color rgb<0.10, 0.70, 0.00>,
         color Orange }    


triangular - couleurs triangulaire -
New in POV-Ray 3.7
(original triangle width : 1 unit)
Example:
pigment{ triangular //max.6 colors/textures 
         color Red,
         color rgb<1.0, 0.4, 0.0>,
         color rgb<1.0, 0.9, 0.0>,
         color rgb<0.5, 1.0, 0.0>,
         color rgb<0.5, 0.5, 1.0>,
         color rgb<0.5, 0.0, 1.0>} 


Sample hexagon with colors 640x480 Sample hexagon with textures 640x480

Example of checker and hexagon:

//--------------------- checker mit colors ------------------
plane{<0,1,0>,0
      texture{
              pigment{checker
                         color White color rgb<0.8,0.65,0.8>
                      scale 0.5}
              finish { diffuse 0.35 reflection 0.5}
             }// end of texture
        }
//---------------------hexagon mit colors -------------------
sphere {<0,0,0>,0.8 translate<0.5,1,1>
        texture {pigment{hexagon  // needs 3 colors!
                         color rgb<1,0.85,0.1>
                         color rgb<1,0.95,0.5>
                         color rgb<0.7,0.3,0.5>
                         rotate<90,-50,0> scale 0.2
                         } // end of pigment
                 normal { wrinkles 0.75 scale 0.025 }
                 finish { diffuse 0.9 specular 0.2}
                } //end of texture
       translate<-0.7,2.25,-1.2>
      } //end of sphere
//--------------------- hexagon mit textures ----------------
sphere {<0,0,0>,0.8
    texture {
      hexagon // needs 3 textures!
      texture {
       Polished_Chrome  //replace Chrome color by:
       pigment{ color rgb<1,0.85,0.1>}
       normal { crackle 0.5 scale 0.05 }
       finish { diffuse 0.9 specular 0.2}
              }// end of 1st texture
      texture {
       Polished_Chrome  //replace Chrome color by:
       pigment{ color rgb<1,0.85,0.1>}
       finish { diffuse 0.9 specular 0.2}
              }// end of 2nd texture
      texture {
       Polished_Chrome //replace Chrome color by:
       pigment{ color rgb<1,0.75,0>}
       normal { bumps 0.5 scale 0.15 }
       finish { diffuse 0.9 }
              }// end of 3rd texture
      scale 0.2 rotate<110,-50,0>
     }// ---------------------------end of texture
  translate<-0.7,2.25,-1.2>
 }//--------------------------- end of sphere ---------

//-------------- Rainbow Stripes Sphere ---------------------
sphere {<0,0,0>,2 scale<1,0.5,1>
        texture {pigment{ radial frequency 15}
                 finish { diffuse 0.9 specular 0.7}
                }// end of texture
        translate<0,1.5,2>}
top

© Friedrich A. Lohmüller, 2010
www.f-lohmueller.de