Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
Gestaltung von Oberflächen mit POV-Ray -
English English English
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  Oberflächengestaltung
  - Farben und Texturen
    Inhalt

    texture Syntax
    Vorgefertigtes
    Farben Do-it-Yourself
    Muster
    Muster Listen
    - Reguläre Muster
    - Random Muster
    - Fractal Muster
    - Besondere Muster
    Warps
   > warp mapping
    uv_mapping
    Mapping
    Überlagerungen

    Eigene Texturen
 
                                           
Mapping with warps
höhere Auflösung.
  Mapping mit warps
  Anpassen von Mustern ("patterns")
            an Oberflächen.

Mit dem Muster-Modifzierer (pattern modifier) "warp" kann man Muster wie "checker", "brick" und andere um Zylinder, Kugeln, Torus und andere Objekte wickeln.
Typen von mapping warps: cylindrical, spherical, toroidal and planar.


top

  Cylindrical Warp
Sample no Cylindrical Warp
brick ohne warp
Sample Cylindrical Warp
brick lateral warp
Beispiel:
pigment { //lateral warp
  brick color rgb<1,1,1>        // mortar
        color rgb<0.8,0.25,0.1> // brick
  brick_size <0.085, 0.0625, 1>
  mortar 0.01
  warp{ cylindrical
        orientation <0,0,1>
        dist_exp 0
      } // end of warp
  } // end of pigment --------------------

Sample Cylindrical Warp
brick top warp
Beispiel:
pigment { // top warp
  brick color rgb<1,1,1>
        color rgb<0.8,0.25,0.1>
  brick_size <0.077, 0.0885, 0.18>
  mortar 0.01
  warp{ cylindrical
        orientation <0,1,0>
        dist_exp 0
      } // end of warp
  } // end of pigment -----------------


top
Spherical Warp
Sample no spherical warp
brick ohne warp
Sample spherical warp
brick mit warp
Klicken Sie auf das Bild
für eine höhere Auflösung.

Beispiel:
pigment {
  brick color rgb<1,1,1>        // mortar
        color rgb<0.8,0.25,0.1> // brick
  brick_size <0.2484, 0.0507, 0.125>
  mortar 0.008
  scale <0.4,1.3,1.1>
  warp{ spherical
        orientation <0,0,1>
        dist_exp 0
      } // end of warp
  } // end of pigment --------------------


top
Toroidal Warp
1) Major Radius Warp
Sample Toroidal Warp
Toroidal Warp
major radius warp
 

Sample Toroidal Warp
A look inside
Klicken Sie auf die Bilder
für eine höhere Auflösung.

Beispiel:
torus { 1, 0.5
 texture{
  pigment {
  brick color rgb<1,1,1>
        color rgb<0.8,0.25,0.1>
  brick_size <0.058,0.0525,0.8>
  mortar 0.0055
  warp { toroidal
         orientation <0,0,1>
         dist_exp 0
         major_radius 0.5
       } // end of warp
  } // end of pigment
  normal {wrinkles 0.75 scale .01}
  }}// end of texture and torus -------

1) Minor Radius Warp
Sample Toroidal Warp
Toroidal Warp
minor radius warp
Klicken Sie auf das Bild
für eine höhere Auflösung.

 

Sample Toroidal Warp
A look inside
Beispiel:
torus { 1, 0.5
 texture{
  pigment {
  brick color rgb<1,1,1>
        color rgb<0.8,0.25,0.1>
  brick_size <1.0,0.0305,0.1>
  mortar 0.006
  rotate <90,0,0>
  warp { toroidal
         orientation <1,0,0>
         dist_exp 0
         major_radius 0.5
       } // end of warp
  } // end of pigment
  normal {wrinkles 0.75 scale .01}
  }}// end of texture and torus -------


top
Planar Warp
Sample no Planar Warp
crackle ohne planar warp
Sample Planar Warp
crackle mit planar warp
Klicken Sie auf die Bilder
für eine höhere Auflösung.

Dies benötigt eine ebenes Bild einer 3D-Textur (aus der Ebene, welche durch den Normalenvektor plane normal in der Entfernung distance längs der Normalen) und extruiert diese Bild entlang der Z-Achse wie ein "image_map".
 
Beispiel:
pigment{
   crackle scale 0.45
   color_map{
     [0.0 color rgbf <1,1,1,0.8>]
     [0.2 color rgbf <1,1,1,0.5>]
     [0.3 color rgb <0.25,0,0>]
     [0.7 color rgb <1,0,0>]
     [1.0 color rgb <1,0,0>]
    }//end of color_map
  scale 0.3 translate<0,0,-1>
  warp { planar <0,0,-1>, -1 
     // plane normal,
     // distance // entlang der Normalen
       // end of warp
  } // end of pigment ------------

top

© Friedrich A. Lohmüller, 2006
http://www.f-lohmueller.de