Descriptions et exemples pour le POV-Ray raytracer par Friedrich A. Lohmüller
Conception de Surface en »texture« avec POV-Ray -
English English English
Italiano Italiano
Deutsch Deutsch

Page d'Accueil
- POV-Ray Tutoriel

  Conception de Surface
  - Coleurs et Textures
    Index

    Syntaxe de texture
    Textures prêtes-à-l'emploi
    Couleurs do-it-yourself
    Motifs - Patterns
    Listes de Motifs
    - Motifs régulaires
    - Motifs par hasard
    - Motifs Fractal
    - Autres motifs
    Warps
    > warp mapping
    uv_mapping
    Mapping
    Superpositions

    Votre textures
 
                                           
Mapping avec warps
résolution plus 'haute.
  Mapping avec warps
  Ajuster motifs aux surfaces

Le modificateur de motifs (pattern modifier) "warp" enroule un motiv comme "checker", "brick" et autres autour de cylindres, sphères, tores et autres objets.
Types de mapping warps: cylindrical, spherical, toroidal et planar.


top

  Cylindrical Warp
Sample no Cylindrical Warp
brick sans warp
Sample Cylindrical Warp
brick lateral warp
Exemple:
pigment { //lateral warp
  brick color rgb<1,1,1>        // mortar
        color rgb<0.8,0.25,0.1> // brick
  brick_size <0.085, 0.0625, 1>
  mortar 0.01
  warp{ cylindrical
        orientation <0,0,1>
        dist_exp 0
      } // end of warp
  } // end of pigment --------------------

Sample Cylindrical Warp
brick top warp
Exemple:
pigment { // top warp
  brick color rgb<1,1,1>
        color rgb<0.8,0.25,0.1>
  brick_size <0.077, 0.0885, 0.18>
  mortar 0.01
  warp{ cylindrical
        orientation <0,1,0>
        dist_exp 0
      } // end of warp
  } // end of pigment -----------------


top
Spherical Warp
Sample no spherical warp
brick sans warp
Sample spherical warp
brick avec warp
Click for a
higher resolution.

Exemple:
pigment {
  brick color rgb<1,1,1>        // mortar
        color rgb<0.8,0.25,0.1> // brick
  brick_size <0.2484, 0.0507, 0.125>
  mortar 0.008
  scale <0.4,1.3,1.1>
  warp{ spherical
        orientation <0,0,1>
        dist_exp 0
      } // end of warp
  } // end of pigment --------------------


top
Toroidal Warp
1) Major Radius Warp
Sample Toroidal Warp
Toroidal Warp
major radius warp
 

Sample Toroidal Warp
A look inside
Click on the images for a higher resolution.
Exemple:
torus { 1, 0.5
 texture{
  pigment {
  brick color rgb<1,1,1>
        color rgb<0.8,0.25,0.1>
  brick_size <0.058,0.0525,0.8>
  mortar 0.0055
  warp { toroidal
         orientation <0,0,1>
         dist_exp 0
         major_radius 0.5
       } // end of warp
  } // end of pigment
  normal {wrinkles 0.75 scale .01}
  }}// end of texture and torus -------

1) Minor Radius Warp
Sample Toroidal Warp
Toroidal Warp
minor radius warp
Click on the image for a higher resolution.
 

Sample Toroidal Warp
A look inside
Exemple:
torus { 1, 0.5
 texture{
  pigment {
  brick color rgb<1,1,1>
        color rgb<0.8,0.25,0.1>
  brick_size <1.0,0.0305,0.1>
  mortar 0.006
  rotate <90,0,0>
  warp { toroidal
         orientation <1,0,0>
         dist_exp 0
         major_radius 0.5
       } // end of warp
  } // end of pigment
  normal {wrinkles 0.75 scale .01}
  }}// end of texture and torus -------


top
Planar Warp
Sample no Planar Warp
crackle sans warp
Sample Planar Warp
crackle avec warp
Click on the images for a higher resolution.
This takes a planar image of a 3d texture (from the pane definded by plane normal in distance along the normal) and extrudes it along the Z-axis like an image_map.
 
Exemple:
pigment{
   crackle scale 0.45
   color_map{
     [0.0 color rgbf <1,1,1,0.8>]
     [0.2 color rgbf <1,1,1,0.5>]
     [0.3 color rgb <0.25,0,0>]
     [0.7 color rgb <1,0,0>]
     [1.0 color rgb <1,0,0>]
    }//end of color_map
  scale 0.3 translate<0,0,-1>
  warp { planar <0,0,-1>, -1 
     // plane normal,
     // distance along the normal
       // end of warp
  } // end of pigment ------------

top

© Friedrich A. Lohmüller, 2006
www.f-lohmueller.de