Scala

Con quest'esempio voglio spiegare la costruzione di una scala semplice.
Per questo dobbiamo definire le dimensioni esteriore: l'altezza, la lunghezza e la larghezza della scala.
Poi fissiamo l'altezza all'incirca di un solo scalino o gradino. Dopo questo il numero di scalini e le dimensioni di un scalino sono calcolate automaticamente.
Un problema speciale é la testura con pietre e commessura: dobbiamo adattare questo motivo con transformazioni all'altezza, alla larghezza e alla profondità dei scalini.
Un file include per usare questo oggetto come un oggetto pronto per l'uso si trova su la mia paggina Oggetti POV-Ray.

Primo di tutto dobbiamo definire le testure e le dimensioni:

#declare Step_Texture =
 texture{
   pigment{ color rgb<0.9,0.8,0.6>}
   finish { diffuse 0.9 phong 0.1}
        } // end of texture
//----------------------------------
// altezza della scala (Y),
#declare Stair_Y = 2.00;
// lunghezza della scala (X)
#declare Stair_X = 4.00;
// larghezza della scala (Z)
#declare Step_Z  = 1.50; 

Poi definissiamo l'altezza all'incirca di un solo gradino:

#declare Step_Height = 0.175;

Di questi valori calculiamo il numero dei gradini e i dimensioni reali d'un solo gradino:

// il numero totale dei gradini
#local N_o_Steps = //Number_of_Steps
     int(Stair_Y/Step_Height);
// caculazione del'altezza reale di un gradino:
#local Step_H = Stair_Y/N_o_Steps;
// -------------------------------------
// la profondita di un gradino in x:
#local Step_X = Stair_X / N_o_Steps;
// -------------------------------------

Dopo si puo montare una scale con un ciclo while ("while loop"):
(qui con elementi seperati chiaro intenzionalmente!)

union{
 #local Nr = 0;   // start steps
 #while (Nr <  N_o_Steps)

  box { <Nr*Step_X, 0, 0>,<Stair_X, Step_H-0.01, Step_Z>
        translate<0,Nr*Step_H,0>
      }

 #local Nr = Nr+1;
 #end //------------ end of while loop
 // end of steps
 texture{Step_Texture}
 //----------------------------------//
 translate<-2.00,0.00, 0.00>
} // end of union 

L'adattamento del'altezza e della larghezza di questo motive ai dimensioni del muro é una cosa molto difficile. Riguardo a problemi con il motivo "bricks" (bricks pattern) vede i commenti nella mia descrizione Torre merlato.