Scala a Chiocciola

Esempio per l'uso di un ciclo while (while loop)
Oggetti: "plane", "box"
Metodi:  "#declare", "union", "while", "intersection", "bounded_by".
Cliccare qui per un esempio!

La forma dei gradini si é definito con l'insieme d'intersezione. ("intersection") di un parallelepipedo a base rettangolare ("box") e due piani verticali ruotato ("plane"). La scala si é costruito con un ciclo while.

//----------- dimensioni ---------------
#declare StH = 0.10; // Stepheight
#declare StT = 0.50; // Stepdeapth, max.
#declare StB = 1.20; // StepWide
#declare StI = 0.40; // StepInnerRadius
#declare StAnz = 40; // Number of Steps
#declare A = 360/20; // Step rotation angle
//---------------------------------------

//---------------------- textures
#declare Stex1 =
 texture{ pigment{color White}
          finish {diffuse 0.85}}
#declare Stex2 =
 texture{ pigment{color White}
          finish {diffuse 0.90}}
#declare Step = //-------------
intersection{
box  {<0,0,-StT>,< StB,StH,StT>
      translate<StI,0,0>
      texture{Stex1}}
plane{<0,0, 1>,0 rotate<0,-W/2,0>
      translate<0,0,0.01>
      texture{Stex2}}
plane{<0,0,-1>,0 rotate<0, W/2,0>
      translate<0,0,0.0 >
      texture{Stex2}}
bounded_by{
 box{<0,0,-StT>,<StB,StH,StT>
     translate<StI,0,0>}}
}//-------------- end of Step

La descrizione della scena per POV-Ray:
"povwend.txt"
o "povwend.pov"

union{
//------------------------- #while - loop --------------------
#declare Nr = 0;    // sets counter Nr on start value
#while (Nr<StAnz)  // check if end value is reached
   object{Step    // Object depending from counter Nr
              translate<0,Nr*StH,0>
              rotate <0,-Nr*A,0>}
#declare Nr = Nr+1; // increase counter by 1
#end               // end of the sector to repeat
//----------------------------------------------------------------
rotate<0,90,0> }
//------------------------------------------------------------ end