// POV-Ray 3.6 Scene File "grid01.pov"
// created by Friedrich A. Lohmueller, 2005
// homepage: www.f-lohmueller.de
//
#version 3.5;
#global_settings { assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9 }} 
// camera -----------------------------------------------------------
#declare Cam0 = camera {//ultra_wide_angle angle 65 
                        angle 75 
                        location  <0.00,  1.50, -3.0>
                        look_at   <0.00, -0.07, -0.00>}
#declare Cam1 = camera {ultra_wide_angle angle 65 
                        location  <2.50,  2.50, -3.0>
                        look_at   <0.20, -0.05, -0.15>}
camera{Cam0}
// sun ---------------------------------------------------------------
light_source{<1500,2500,-2500> color rgb<1,1,1>}

// sky ----------------------------------------------------------
sphere{<0,0,0>,1 hollow //keep attention: keep sun lower than sky
       texture{pigment{gradient <0,1,0>
                       color_map{[0 color rgb<1,1,1>]
                                 [1 color rgb<0,0,1>]}
                       quick_color rgb<0,0,1> }
               finish {ambient 1 diffuse 0}
              }
       scale 10000}
//----------------------------------------------------------------

fog{fog_type   2
    distance   15
    color      rgb<1,1,1>*0.9 // rgb<1,0.75,0>
    fog_offset 0.5
    fog_alt    0.5
    turbulence 0.8}
//---------------------------------------------------------------

//----------------------------------------------------<<< Raster macro
#macro Raster(RScale, HLine) 
       pigment{ gradient x scale RScale
                color_map{[0.000   color rgbt<0,0,0,0>]
                          [0+HLine color rgbt<0,0,0,0>]
                          [0+HLine color rgbt<1,1,1,1>]
                          [1-HLine color rgbt<1,1,1,1>]
                          [1-HLine color rgbt<0,0,0,0>]
                          [1.000   color rgbt<0,0,0,0>]} }
       finish { phong 0.1 }
 #end// of Raster(RScale, HLine)-macro    
//---------------------------------------------------<<<< Grid macro
#macro Grid (RasterScale, RasterHalfLine, Background_pigment)
     //------------------------------------------------------
plane{<0,1,0>, 0      // uses layerd textures!!!!
       texture{Background_pigment  finish { phong 0.1}}
       texture{Raster( RasterScale, RasterHalfLine) rotate<0,0,0> }
       texture{Raster( RasterScale, RasterHalfLine) rotate<0,90,0>}
      scale 1}
#end // end of macro  Grid (RasterScale, RasterHalfLine, Background_Texture)
//---------------------------------------------------------------------------
// use it:
object{ Grid ( 0.5, 0.040, pigment{color rgb<1,1,1>*1.25} ) }

//----------------------------------------------------------------------- end