Usare la camera 'orthographic'
(q.v. anche l'immagine in margine!).
Se si guarda con una camera orthographica camera verticalmente verso un piano,
possiamo rapportare le dimensioni di un oggetto direttamente con il piano su lo sfondo quadrettato
dietro l'oggetto!
Con la camera 'orthographic' non c'è nessun accorciamento di prospettiva!
Questo è una proiezione parallela semplice!
Una camera orthographica molto semplice:
//----------------------------------------------<<<
camera{ orthographic
location < 0.00, 1.60,-10.00>
right x*image_width/image_height
angle 50
look_at < 0.00, 1.60, 0.00>;
} //---------------------
//----------------------------------------------<<< |
Una camera orthographica più confortevole:
'orthographic' o 'perspective' :
// choosing the camera number:
//------------------------------------<<<
#declare Camera_Number = 0 ;
//------------------------------------<<<
#switch ( Camera_Number )
#case (0) // front view orthographic
#declare Orthographic_On = 1;
#declare Camera_Position = < 1.55, 1.60,-10.00>;
#declare Camera_Look_At = < 1.55, 1.60, 0.00>;
#declare Camera_Angle = 20;
#break
#case (1) // diagonal view perspective ('normal')
#declare Orthographic_On = 0;
#declare Camera_Position = <15.00, 8.00,-15.00>;
#declare Camera_Look_At = < 0.50, 1.70, -0.50>;
#declare Camera_Angle = 25;
#break
#end // of "#switch ( Camera_Number )" ----------
//----------------------------------------------<<<
camera{ #if (Orthographic_On = 1) orthographic #end
location Camera_Position
right x*image_width/image_height
angle Camera_Angle
look_at Camera_Look_At
} //---------------------
//----------------------------------------------<<< |
Fare une sezione di un oggetto con la camera orthographica
Con la camera di tipo 'orthographic' per es. come la seguente possiamo
fare una sezione di nostri oggetti.
Senza 'look_at', ma con il vettore 'direction'!
//--------------------------------------------<<<
camera{ orthographic
location < 0.00, 1.75, -1.80>
right x*image_width/image_height
angle 88
direction <0,0,1>
} //---------------------
//----------------------------------------------<<< |
Ma c'è un metodo molto più elegante per ottenere una sezione
con la 'intersection' con un 'box' corrispondente.
Cosi siamo anche in grado di scegliere il colore della superficie della sezione.
(q.v. l'immagine in margine!)
|
Vista perspectiva.
Guardare da sinistra con una camera 'normale'.
Vista orthographica.
Una camera guardando parallelemente.
La veduta anteriore orthographica
Sezione d'oggetto con la camera 'orthographic'
Camera 'orthographic' e 'intersection' con un 'box'.
|
