Utiliser la caméra 'orthographic'
(Voir aussi l'image ci-contre !).
Si nous voyons avec une caméra 'orthographic' vertical vers un plan,
nous pouvons comparer les dimensions de notre objets directement avec le plan et le arrière-plan quadrillé
derrière de l'objet !
Avec la caméra orthographique il n'y a pas des raccourcissements de perspective des objets plus éloigné.
Il est simplement une projection parallèle !
Une caméra orthographique tres simple :
//----------------------------------------------<<<
camera{ orthographic
location < 0.00, 1.60,-10.00>
right x*image_width/image_height
angle 50
look_at < 0.00, 1.60, 0.00>;
} //---------------------
//----------------------------------------------<<< |
Une caméra orthographique plus confortable :
'orthographic' ou 'perspective' :
// choosing the camera number:
//------------------------------------<<<
#declare Camera_Number = 0 ;
//------------------------------------<<<
#switch ( Camera_Number )
#case (0) // front view orthographic
#declare Orthographic_On = 1;
#declare Camera_Position = < 1.55, 1.60,-10.00>;
#declare Camera_Look_At = < 1.55, 1.60, 0.00>;
#declare Camera_Angle = 20;
#break
#case (1) // diagonal view perspective ('normal')
#declare Orthographic_On = 0;
#declare Camera_Position = <15.00, 8.00,-15.00>;
#declare Camera_Look_At = < 0.50, 1.70, -0.50>;
#declare Camera_Angle = 25;
#break
#end // of "#switch ( Camera_Number )" ----------
//----------------------------------------------<<<
camera{ #if (Orthographic_On = 1) orthographic #end
location Camera_Position
right x*image_width/image_height
angle Camera_Angle
look_at Camera_Look_At
} //---------------------
//----------------------------------------------<<< |
Sections des objets avec la caméra 'orthographic'
Avec la caméra orthographique comme par ex. la suivant
nous pouvons aussi faire des sections d'un objet.
Sans 'look_at' mais avec le vecteur 'direction' !
//--------------------------------------------<<<
camera{ orthographic
location < 0.00, 1.75, -1.80>
right x*image_width/image_height
angle 88
direction <0,0,1>
} //---------------------
//----------------------------------------------<<< |
Mais il y a une méthode plus élégant pour obtenir ce resultat.
On peut faire une 'intersection' avec un 'box' correspondant.
Avec cette méthode nous pouvons aussi choisir le coleur de la surface de la section.
(Voir l'image ci-contre !)
|
Une vue 'perspective'
On regarde de gauche avec une caméra 'normal'.
Vue orthographique.
La caméra regarde parallèlement.
Une vue de face orthographique
Section de l'objet avec caméra 'orthographic'
Caméra 'orthographic' et 'intersection' avec un 'box'.
|
