Descriptions et exemples pour le POV-Ray raytracer par Friedrich A. Lohmüller.
 English English English
Italiano  Italiano
Deutsch 
Survol de mes macro Survol objets macro macro "Segment_of_Torus (...)"

Cette forme est définie comme "macro" dans mon include file "shapes_lo.inc":

Cylinder_Ring_Segment

Segment_of_CylinderRing

    Segment_of_CylinderRing
 
syntaxe générale : 
object{ Segment_of_CylinderRing (R_out, R_in, Height, Segment_Angle)
        texture{ ... ... }
      } // end of object ------------
Ici :
R_out = le rayon extérieur du anneau cylindrique,
R_in = le rayon intérieur du anneau cylindrique,
Height = l'hauteur du section d'anneau,
Segment_Angle = l'angle della section d'anneau, orienté à main gauche.
Pour "Segment_Angle = 0" il en résulte un anneau complet ou un tuyau.
Pour compatibilité le macro vieux du "Cylinder_Ring_Segment"
existe encore - ici l'angle est orienté à main droit!
Exemples : 
#include "shapes_lo.inc"
// --------------------------------------------------------------------------
object{ Segment_of_CylinderRing ( 3.75, 2.25, 0.20, -300)
        texture { Chrome_Metal
                  finish { ambient 0.1 diffuse 0.85  phong 1}
                } // end of texture
        scale <1,1,1> rotate<0,0,0> translate<0,0,0>
      } // ------------------------------------------------------------------

// --------------------------------------------------------------------------
object{ Segment_of_CylinderRing ( 1.75, 1.50, 2.00, -270)
        texture{ pigment {color White*1.1}
                 finish { ambient 0.15 diffuse 0.85 phong 1 }
               } // end of texture
      } // ------------------------------------------------------------------

// --------------------------------------------------------------------------
object{ Segment_of_CylinderRing ( 2.50, 3.00, 1.00, -80)
        texture { pigment{ color rgb< 0.7, 1, 0.0> }
                  finish { ambient 0.15 diffuse 0.75  phong 1 reflection 0.2}
                } // end of texture
      } // ------------------------------------------------------------------

// --------------------------------------------------------------------------
object{ Segment_of_CylinderRing ( 1.1, 0.80, 1.50,  0)
        texture { pigment{ color rgb< 1,0.7, 0.0> }
                  finish { ambient 0.15 diffuse 0.75  phong 1 reflection 0.2}
                } // end of texture
      } // ------------------------------------------------------------------

Macro en détail:

D'abord on soustrait du cylindre avec le rayon R_out un cylindre plus petit avec le rayon R_in, par faire un'intersection du premier cylindre avec l'inverse (complément) du second cylindre. Après cela on utilise 2 parallélépipèdes tournés ("box") pour découper la section desirée.
Dans ce cas il faut tenir compte de deux cas :
1. abs(Segment_Angle) <= 180 degrés (juste l'intersection de la tore et des deux boites) et
2. abs(Segment_Angle) > 180 degrés (juste l'intersection de la tore et l'union des deux boites) : 
//--------------------------------------------------- Segment_of_CylinderRing macro
#macro  Segment_of_CylinderRing ( R_out, R_in, Height, Segment_Angle)

#local D = 0.0001; // just a little bit

 #if (Height = 0 ) #local  Height = D; #end
 #if (Height < 0 ) #local  D = -D; #end

 #if (R_out < R_in) #local X=R_out; #local R_out=R_in; #local R_in=X; #end

 #if (Segment_Angle < 0)
      #local Negativ_Flag = 1;
      #local Segment_Angle = -Segment_Angle;
 #else
      #local Negativ_Flag = 0;
 #end


 #if (Segment_Angle >= 360) #local Segment_Angle = mod (Segment_Angle, 360); #end

 intersection{
   cylinder { <0,0,0>,<0,Height,0>, R_out
            } // end of outer cylinder  ----------
   cylinder { <0,-D,0>,<0,Height+D,0>, R_in
              inverse
            } // end of inner cylinder  ----------


  #if (Segment_Angle > 0) // ------------------------------------------------------
  #if (Segment_Angle >= 180)
  union{
  #end // then use union!

   box { <-R_out+D,-D,0>,< R_out+D, Height+D, R_out+D>
         rotate<0,0,0>
       }// end of box

   box { <-R_out+D,-D,-R_out+D>,< R_out+D, Height+D,0>
         rotate<0,-Segment_Angle,0>
       }// end of box

  #if (Segment_Angle >= 180)
   } // end of union
  #end // end of union, if union is used!

 #if (Negativ_Flag = 0)  rotate<0,-Segment_Angle,0>
 scale<-1,1,-1>
  #end // of "#if (Segment_Angle > 0)" --------------------------------------------

  } // end of intersection

#end // end of macro ------------------------- end of Segment_of_CylinderRing --

Les images suivantes montrent comment fonctionnent ces macros
(Les boites sont affichées en texture de verre transparente) :
 
Cylinder_Ring_Segment 145 degrees Cylinder_Ring_Segment 215 degrees
abs(Segment_Angle) <= 180 degrees
R_out = 1.25, R_in = 0.75, Angle = -145 		abs(Segment_Angle) > 180 degrees
R_out = 1.25, R_in = 0.75, Angle = -215





Survol de mes macro Survol objets macro macro "Segment_of_Torus (...)"
© Friedrich A. Lohmüller, 2010
email email: (legacy email redacted)
homepage:www.f-lohmueller.de