Page d'Accueil
- POV-Ray Tutoriel
Images stéréo et
Animation stéréo
Index
Vision croisée
Images stéréo simples
Images stéréo avancées
Combiner images
> Animation stéréo 1
Animation stéréo 2
Exemples d'anims stéréo
|
Animation stéréo (1)
|
Comment faire une série
des images stéréo pour une animation.
1.1: Faire un fichier de la scène stéréo
comme indiqué à ' Images stéréo avancées '.
There we use 'frame_number' to control right/left eye view:
(' frame ' = une image dans une animation )
nombre frame impair 1, 3, 5, ... = vue de droit,
nombre frame pair 2, 4, 6, ... = vue de gauche,
frame_number 0 = vue non-stéréo pour tester la scène.
Pour une animation de par ex. 30 frames,
nous devon faire 2*30=60 frames!
Animation avec 'clock' et 'frame_number':
1. Contrôle d'animation basé sur frame_number:
Ici nous devons utiliser un nombre de frame nouveau
nommé 'Frame'.
Pour nombres de frame impair :
#declare Frame = int( frame_number/2 );
autrement : #declare Frame = int((frame_number+1)/2);
et comme un nombre de frames nouveau :
#declare EndFrame = final_frame/2;
2. Contrôle d'animation basé sur clock:
Ici nous devons utiliser clock_delta
per adapter il temps interne aux valeurs de 'clock' !
(built-in clock_delta = la difference entre les valeurs de 'clock')
Avec par ex. Initial_Clock=0, Final_Clock=1,
Initial_Frame=1 et Final_Frame=60,
nous avons pour frame_numbers impair :
#declare Time = clock ;
et pour frame_numbers pair :
#declare Time = clock - clock_delta;
Dans un fichier de la scène POV-Ray Stereo_Ani_00_.pov
nous déclarons une caméra stéréo come suivante :
(Pour plus des détails voir le fichiers de la scene à gauche !!! )
// -------------------- // stereo view:
#declare Stereo_On = 1;
#if( Stereo_On = 1 )
#declare Eye_Distance = 0.4;
// Stereo Animations frame counting:
// stereo starts at frame_number = 1
// odd frame numbers 1,3,5,... = right
// even frame number 2,4,6,... = left
// stereo: frame 1~60 -> frame pair = 1~30!
#if((frame_number/2)!=int(frame_number/2))
// odd frame_number
#declare Eye_Distance =-Eye_Distance;
#declare Time = clock ;
#declare Frame = (frame_number+1)/2 ;
#else // even frame_number
#declare Eye_Distance = Eye_Distance;
#declare Time = clock - clock_delta ;
#declare Frame = (frame_number )/2 ;
#end
#declare EndFrame = final_frame/2;
#else // Stereo_On = 0
#declare Eye_Distance = 0;
#declare Time = clock +0.0 ;
#declare Frame = frame_number ;
#declare EndFrame = final_frame ;
#end // of "#if( Stereo_On = 1 ) "
//------------------------------------------
#declare Camera_Position= < 0.0, 2.0,-4.0>;
#declare Camera_Look_At = < 0.0, 2.0, 0.0>;
#declare Camera_Angle = 65 ;
//------------------------------------------
camera{
location Camera_Position
+ Eye_Distance/2
* vnormalize(
vcross(
Camera_Look_At-Camera_Position,
<0,1,0>
)// vcross
)// vnormalize
right x*image_width/image_height
angle Camera_Angle
look_at Camera_Look_At
} // end camera
// .... lights and background ...
// .... and an object in scene:
object{
Wire_Box(<-1,-1,-1>,<1,1,1>,0.1,0)
texture{pigment{color rgb<1,1,1>*1.2}}
#if(frame_number != 0)// stereo
rotate<0, Time*90 ,0>
// or optional:
// rotate<0,(Frame-1)/EndFrame*90,0>
#end
translate<0,2.0,0>
} // --------------------------------------- |
Pour un rendu quadratique, nous avons mis en
ligne de commande:
" +w240 +h240 ".
Avec POV-Ray 3.7, nous pouvons utiliser la sortie jpeg par
" +w240 +h240 +fj100 ".
|
La situation d'une caméra en mouvement libre:
emplacement de la caméra non-stéréo (violet),
positions de l'oeil droit et gauche (jaune / rouge),
avec point look_at mobile (jaune vert).
La scène en non-stereo, rendue avec le fichier de
la scène (sans fichier ini !).
frame_number default est 0.
D'où la
Half_Eye_Distance est 0 et le rendering
de la scène fait une vue non-stéréo.
|
1.2: Le fichier ini pour une animation stéréo
Le nome : Stereo_Ani_00_.ini:
|
Antialias=On
Antialias_Threshold=0.3
Antialias_Depth=3
Input_File_Name=Stereo_Ani_00_.pov
Initial_Frame=1
Final_Frame=60
; 1~60 for 30 images
Initial_Clock=0
Final_Clock=1
Cyclic_Animation=on
Pause_when_Done=off |
Remarque:
frame_number 0 est réservé aux non-stéréo vue!
L'exécution de ce fichier
fait une série de 30 paires d'images stéréo:
30 vues œil droit: numérotés 01,03,05,...,29 et
30 vues œil gauche. numérotés: 02,04,06,...,30.
POV-Ray 3.6 / 3.7
Fichier de la scène stéréo :
Stereo_Ani_00_.pov
Fichier ini de l'animation stéréo :
Stereo_Ani_00_.ini
|
Le point de vue de l'œil droit.
Stereo_Ani_00_01.jpg
|
Le point de vue de l'œil gauche.
Stereo_Ani_00_02.jpg
|
Continue with 2.1: Combiner une série des images stéréo.
|
|
