Home
- POV-Ray Tutorial
- POV-Ray Beispiele
Inhaltsübersicht
- Geometrie
- Architektur
- Haus - Teil 1
- Haus - Teil 2
- Haus - Teil 3
- Dach
- Turm mit Zinnen
- Fenster u. Tür
- Treppen
- Pyramide
- Säulen
- Bogen
- Zäune
- Möbel
- Haushalt
- Technik
|
|
Haus Teil 2
Objekte: "box", "plane".
Methoden: "difference", "union", "inverse", "#declare".
Die Konstruktion eines Hauses
(Innenraum ausgehöhlt, Dachflächen)
Das Aushöhlen des Innern geschieht durch Abziehen eines um die Wanddicke kleineren
Quaders - hier am einfachsten realisiert durch Differenzbildung ("difference"):
Grundkörper des Hauses minus Quader in Größe des Innenraumes.
Eine Include-Datei mit der man dieses Objekt als Fertig-Objekt verwenden kann
findet man auf meiner POV-Ray Objects-Seite.
|
//-------------------------------------
#declare Wall_Texture_1 =
texture{ pigment{color rgb<1,1,1>*1.1}
normal {bumps 0.5 scale 0.005}
finish {diffuse 0.9}
} // end of texture
#declare Wall_Texture_2 =
texture{ pigment{color rgb<1,1,1>*1}
finish {diffuse 0.9}
} // end of texture
//-------------------------------------
#declare Wd = 0.20 ; // Wanddicke
// Das Aushöhlen des Hauskörpers
difference{ //-------------------------
box { <-Hx,0,0>,< Hx,Hy,Hz>
texture { Wall_Texture_1}
} // end of box -------------------
plane{ <0,-1,0>,0
texture { Wall_Texture_2}
rotate<0,0,Roof_Angle>
translate<0,Hy,0>
} // end of plane ----------------
plane{ <0,-1,0>,0
texture { Wall_Texture_2}
rotate<0,0,-Roof_Angle>
translate<0,Hy,0>
} // end of plane ----------------
// inside caved out - innen ausgehölt
box { <-Hx+Wd,0.10,Wd>,<Hx-Wd,Hy,Hz-Wd>
texture {Wall_Texture_2}
}
}// end of difference ----------------- |
|
|
|
Die Dachflächen:
Die Dachflächen werden durch Quader der Höhe der Dachdicke gebildet, welche um den
Dachneigungswinkel gedreht werden und an ihre Position an der Oberkante der Hausmauern
geschoben werden.
#declare Roof_Texture= // Dach-Textur
// layered textures
// überlagerte Texturen
texture{
pigment{color rgb<.55,.09,.09>*1.3}
normal {gradient z scallop_wave
scale<1,1,0.15>}
finish { diffuse 0.9}
} // end of texture 1 ----------------
texture{
pigment{
gradient x
color_map{
[0.00 color rgbt<1,1,1,1>]
[0.90 color rgbt<1,1,1,1>]
[0.95 color rgb<1,1,1>*0.1]
[1.00 color rgb<1,1,1>*0.1]}
scale 0.25}
finish { diffuse 0.9}
} // end of texture ------------------
//--------- Ende der Dach-Textur
#declare Roof_D = 0.10; // Dachdicke
#declare Roof_O = 0.20; //überhang
#declare Roof_L = Hx+0.8;// try!!
// Die Dachflächen:
box{ // linke Dachfläche
<-Roof_L, 0, -Roof_O>,
< Roof_D/2,Roof_D,Hz+Roof_O>
texture{ Roof_Texture
translate<-0.05,0,0>}
rotate<0,0, Roof_Angle>
translate<0,Hy,0>
}
box{ // rechte Dachfläche
<-Roof_L, 0, -Roof_O>,
< Roof_D/2, Roof_D,Hz+Roof_O>
texture{ Roof_Texture
translate<-0.05,0,0>}
rotate<0,0, Roof_Angle>
translate<0,Hy,0>
scale<-1,1,1> // gespiegelt in x
}
//------------------------- Ende Dach |
|
Zugehörige Szenenbeschreibung für POV-Ray:
".txt"-Datei oder
".pov"-Datei
|
Gebrauchsferige POV-Ray Objekte als
Include-Dateien mit Beispieldateien findet man
auf der POV-Ray-Objects-Seite.
|
