Descriptions and Samples for the POV-Ray Raytracer by Friedrich A. Lohmüller

Construction of a Canoe
and positioning on the water
by "transform{...}"

Objects:    "sphere", "box" "plane"
Methods: "declare", "union", "intersection", "transform{...}"

The shape of an ellipsoid forms the outside of a canoe. This shape is caved out by a smaler scaled version of itself. ("intersection" with "inverse")
From this an ellipsoid will be cut off:

#declare Canoe_outside=
sphere {<0,0,0>,1 scale <3,1.5,1>  translate<0,0.5,0> }
//-----------------------------------------------------
#declare Canoe =
intersection{
 object{ Canoe_outside }
 object{ Canoe_outside scale <0.98,0.95,0.94> inverse}
 sphere {<0,0,0>,1 scale <2.5,1,20> translate<0,1.3,0> inverse}
 texture{pigment{color White*1.1}
 finish {ambient 0.45 diffuse 0.55 phong 1}}
 } // end of outside structure of the canoe -------------------

Naturally we should addmit us some seats inside of the canue!

If we place the canoe simply on the surface of the water the user will get wet feed!
To avoid this we must subtract the outside shape of the canoe from the water plane right at the same place we want to position our canoe
Like this a canoe is pure fun!

#declare Canoe_Position1
  = transform{ rotate < 0,30, 0> translate<0,0,1>}

//-------------------------------------< place canoe
object{ Canoe transform Canoe_Position1}

// -----------------------------------< hole in the water
difference{
plane{<0,1,0>, 0 } // the water
object{Canoe_outside
       transform Canoe_Position1 } // the hole
   texture{Polished_Chrome
                    normal {crackle 1 scale 5
                            turbulence 1 translate<0,0,5>}
                    finish {ambient 0.35 diffuse 0.25
                            reflection 0.40}}
          }// end of difference
//---------------------------------------------------- end

The real effectivness of this method naturally comes into play only if we can afford more than one canoe!

The complete scene description for POV-Ray is here!