Descriptions and Samples for the POV-Ray Raytracer by Friedrich A. Lohmüller

deutsche Version

Arch (for doors or bridges)

Octagon

4 Arches

The Construction with 4 Arches upon 4 Columns.

frontside view (view in +z direction)

Construction of the details:

1. An arch as a difference of a box and a cylinder:
Avoid coincident surfaces!

//-------------------- arch -------------------------
#declare Arch = difference{
 box {<-1.1,0,-0.1>,< 1.1,1.1,0.1>}
 cylinder {<0,0,-0.11>,<0,0,0.11>,0.9 }
 texture{pigment{color White}
         normal{bumps 0.4 scale 0.007}
         finish {ambient 0.15 diffuse 0.85 phong 1}}
}//-------------------------------------------------- 

2. A pillar with a cone and rings (torus) at both ends:

//------------- Pfeiler (pillar) --------------------
#declare Pillar = union{
 torus{0.10,0.05 translate<0,1.45,0>}
 torus{0.12,0.05 translate<0,0.04,0>}
 cone {<0,0,0>,0.12,<0,1.5,0>,0.1}
 texture{pigment{color White}
         normal{bumps 0.4 scale 0.007}
         finish {ambient 0.15 diffuse 0.85 phong 1}}
}//---------------------------------------------------

3. Four arches placed upon 4 pillars and then raised upon a pyramid of stairs.

#declare Arches =
union{// --------arch upon columns -------------------
object{Pillar translate<-1,0,-1>}
object{Pillar translate< 1,0,-1>}
object{Pillar translate<-1,0, 1>}
object{Pillar translate< 1,0, 1>}
object{Arch rotate<0, 0,0> translate< 0,1.5, 1>}
object{Arch rotate<0, 0,0> translate< 0,1.5,-1>}
object{Arch rotate<0,90,0> translate< 1,1.5, 0>}
object{Arch rotate<0,90,0> translate<-1,1.5, 0>}
} // -------------------------------------------------

#declare Steps =
union{ // -------------------- stairs ----------------
box{<-1.20,0.30,-1.20>,<1.20,0.45,1.20>}
box{<-1.50,0.15,-1.50>,<1.50,0.30,1.50>}
box{<-1.80,0.00,-1.80>,<1.80,0.15,1.80>}
 texture{T_Stone8 scale 0.3 pigment{quick_color White}
         normal{bumps 0.4 scale 0.007}
         finish {ambient 0.15 diffuse 0.85 phong 1}}
 }//--------------------- end of the stairs-----------

And finally:
4. All together combined in a "union" for being transformed freely:

// -------- all together now ----------- union{object{Arches translate<0,0.45,0>} object{Steps} scale <1,1,1> rotate<0,0,0> translate<0,0,0> }// end of union //---------------------------------- end

Click here for the complete scene description for POV-Ray:
".txt" file or ".pov" file

Arch (for doors or bridges)

Octagon

© Friedrich A. Lohmüller, 2003     email: (legacy email redacted)