Descrizioni ed esempi per POV-Ray di Friedrich A. Lohmüller,
 

Cicli in POV-Ray     
English English English
Français français
Deutsch Deutsch

Home
- POV-Ray Tutorial

  Cicli con POV-Ray
  1. For e While
       Comparazione
  2. Trasformazioni
       lineari
  3. Trasformazioni
       circolari
  4. Moebius etc.
  5. Viti e spirali
  6. Spirali
       intrecciate
  7. Chiocciole
       e ammoniti
  8. Spirali sferiche 1
>9. Spirali sferiche 2
 10. Spirali Fibonacci
                                         
 
 
  - Download

Spirali sferiche 2

Trasformazioni circolari sulla superficie di una sfera:
#declare Element =
sphere{ <0,0,0>,0.05
        texture{
          pigment{ color rgb<0.8,0.4,0>}
          finish { phong 1
            reflection{0.3 metallic 0.5}}
               } // end texture
} // end sphere -----------------------

#local Drill = 0.45;
#local Stripes = 8;
union{ //------------------------------

 // spirals ---------------------------
 #local NrB =  0;     // start
 #local EndB = 2000; // end
 #while (NrB < EndB)
   #local Nr =  0;     // start
   #local End = Stripes; // end
   #while (Nr < End)  // loop
    object{ Element
    // * add scale here!
            translate<1,0,0>
            rotate<0, 0,-90+NrB *180/EndB>
            rotate<0,Drill*NrB* 360/EndB,0>
            rotate<0,Nr*360/End,0>
          } //----------------------
   #local Nr = Nr + 1;    // next Nr
   #end // ---------------  end of loop

 #local NrB = NrB + 1;    // next Nr
 #end // ---------------  end of loop
 // end of spirals ---------------------

rotate<0,0,0>
translate<0,1,0>
} // end of union ---------------------
Ridimensionamento degli elementi de la spirale in direzione z:
  scale 1+<0,0,4>
     *cos( radians( -90 +NrB * 180/EndB ) )







Se si sostituisce l'elemento con questo:
#declare Element =
union{
 sphere{ <0,0,0>,0.05 }
 sphere{ <0,0,0>,0.05 translate<-0.04,0,0>
         texture{
           pigment{ color rgb<1,1,1>*0.95}
           normal { bumps 0.75 scale 0.01}
           finish { phong 0.7 }
                } // end of texture
        }
 } // end union -------------------------- 
e se infine aggiungiamo una texture globale come questo:

 texture{ pigment{ color rgb<1,0.4,0>}
          normal { bumps 0.75 scale 0.02}
          finish { phong 1
             reflection{ 0.1 metallic 0.5}}
          }
avremo l'immagine seguente (a destra):



top

© Friedrich A. Lohmüller, 2014
http://www.f-lohmueller.de