Page d'accueil
- Tutoriel POV-Ray
Objets Géométriques
table des matières
Objets de Base
Objets avec macro + CSG
Objets dans "shapes3.inc"
D'autres objets comme macros
Objets 3D text
Autre Objets
Objets Non-CSG
height_field + HF macros
- height_field par images
- height_field réglé
- height_field par fonctions
>height_fields massive
>HF - monts et vaux
- HF_Square
- HF_Sphere
- HF_Cylinder
- HF_Torus
Isosurface
|
|
|
" height_field " localisé
et
" height_field " massive
|
|
Nous pouvons atteindre un "height_field" localisé par ex.
avec interférer un "height_field" de fonction
avec l'une
des fonctions de motif spéciaux
"spherical" et "boxed":
#declare HF_Res_X = 1024; // number of points in x
#declare HF_Res_Z = 1024; // number of points in z
#declare SF =
function {
pigment {
spherical
color_map {
[0.0, color 0.0 ]
[0.5, color 0.5 ]
[1.0, color 1.0 ]
} // end color_map
scale <0.5,1,0.5>
translate<0.5,0,0.5>
} // end pigment
} // end function
#declare HF_Function =
function(x, y, z)
{1+f_snoise3d(x*10,y*10,z*10)*0.3 * SF(x,y,z).gray}
#declare HF_Amplitude = 0.5;
#declare D = 0.00001; // just a little bit!
height_field{
function HF_Res_X, HF_Res_Z
{ HF_Function(x,0,y) * HF_Amplitude }
//smooth
//water_level 0
translate<0,-0.42,0>
scale <1,1,1>
texture { pigment{ color rgb<0.96,0.87,0.73>}
normal{ bumps 0.25 scale 0.005 }
} // end of texture
}//------------------------------------------------ |
|
f_noise fonction + spherical pattern
"height_field" par la fonction
function{1+f_snoise3d(x*10,y*10,z*10)*0.3
multipliée par la function de motif " spherical "
"height_field" par la fonction
function{1+f_snoise3d(x*10,y*10,z*10)*0.3
multipliée par fonction de motif " boxed "
|
|
Comment creer un corps massive de "height_field" :
Un "height_field" soi-même est seulement une peau mince des triangles - a " mesh ".
Si nous avons besoin d'un corps massive pour des operations CSG
("union","merge","difference" or "intersection")
nous pouvons gagner cela par une conversion d'un "height_field"
dans un block massive avec une surface de "height_field" à laide de
"intersection" par une "box".
#declare HF_Res_X = 1024; // number of points in x
#declare HF_Res_Z = 1024; // number of points in z
#declare HF_Function = function{0.1+0.1*sin(x*30)}
#declare HF_Amplitude = 0.25;
#declare D = 0.00001; // just a little bit!
intersection{
height_field{
function HF_Res_X, HF_Res_Z
{ HF_Function(x,0,y) * HF_Amplitude }
//smooth
//water_level 0
translate<0,D,0>
} // end HF
box{ <D,-0.2,D>,<1-D,0.2-D,1-D>
} // end box
texture { pigment{ color rgb<0.75,0.5,1> }
finish { phong 1 }
} // end of texture
translate<0,0.21,0>
scale <1,1,1>
}// end intersection ------------------------------ |
|
"height_field" massive par une fonction
avec "intersection" par "box"
|
|
