#declare Element =
sphere{ <0,0,0>,0.05
texture{
pigment{ color rgb<0.7,0,0>}
finish { phong 1
reflection{0.3 metallic 0.5}}
} // end texture
} // end sphere -----------------------
union{ //------------------------------
// spiral ----------------------------
#local Nr = 0; // start
#local End = 6000; // end
#while (Nr < End) // loop
object{ Element translate <1,0,0>
rotate<0,0,-90+Nr*180/End>
rotate<0,12*Nr*360/End,0>
}
#local Nr = Nr + 1; // next Nr
#end // --------------- end of loop
// end of spiral ---------------------
rotate<0,0,0>
translate<0,1,0>
} // end of union --------------------- |
Für eine Doppelspirale ersetzt man den oberen Spiralen-Teil durch Folgendes:
// double spiral --------------------
#local Nr = 0; // start
#local End = 6000; // end
#local Turns = 7;
#while (Nr < End) // loop
object{ Element translate<1,0,0>
rotate<0, 0,-90+Nr*180/End>
rotate<0, Turns*Nr*360/End,0>
}
object{ Element translate<-1,0,0>
rotate<0, 0,-90+Nr*180/End>
rotate<0,-Turns*Nr*360/End,0>
}
#local Nr = Nr + 1; // next Nr
#end // --------------- end of loop
// end of double spiral -------------- |
........ :
|
|
