Schloss - 3. Wassergraben

// ground -----------------------------
difference{
  plane{<0,1,0>, 0}
  box{  <-15,-5,-15>,<15,1,15>}
   texture{
    pigment{ color rgb<0.82,0.57,0.35>}
    normal { bumps 0.75 scale 0.025 }
    finish { phong 0.1 }
   } // end of texture
  }// end of difference  --------------
// water ------------------------------
 box{<-15,-5,-15>,<15,-0.80,15>
   texture{
    T_Green_Glass
    normal {ripples 0.5 scale 0.25}}}
//-------------------------------------

//------------------------------------------------------
#declare Walltex =
  texture{pigment{color White}
          finish {diffuse 0.9 phong 1}}
#declare Rooftex =
  texture{pigment{color rgb<0.4,0,0>}
          finish {diffuse 0.9 phong 1}}
// Grabenmauer -----------------------------------------
#declare G_Mauer =
box {<-15.3,-6,-0.3 >,< 15.3,  0.2,0.3> rotate<-5,0,0>
     texture{Walltex}}
// zeichne 4 GrabenMauern ------------------------------
object{G_Mauer rotate<0,  0,0> translate<  0,-0.25,-15>}
object{G_Mauer rotate<0,180,0> translate<  0,-0.25, 15>}
object{G_Mauer rotate<0, 90,0> translate<-15,-0.25,  0>}
object{G_Mauer rotate<0,-90,0> translate< 15,-0.25,  0>}
//----------------------- Turm  ------------------------
#declare TR =  2.0;   //TurmRadius
#declare TH =  5.0;   //TurmHöhe
//------------------------------------------------------
#declare Turm =  union{     //definiert Objekt "Turm"
cone{<0,-TH,0>,TR+1.0,<0,0,0>,TR   texture{Walltex}}
cylinder {<0,0.0,0>,<0, TH,0>,TR   texture{Walltex}}
cylinder {<0,0.0,0>,<0,0.1,0>,2.05 texture{Walltex}}
cylinder {<0,2.5,0>,<0,2.6,0>,2.05 texture{Walltex}}
cone{<0,0,0>,TR+0.5,<0,TR+0.5,0>,0
                    translate<0,TH,0> texture{Rooftex}}
cone{<0,0,0>,TR -0.2,<0,2*TR+0.5,0>,0
                    translate<0,TH,0> texture{Rooftex}}
}// ------------ end of tower - Ende Turm --------------
//------------------ the walls - die Mauern ------------
#declare Mauer = union{
  box {<-4  , 0,-0.3>,<  4,3.5,0.3> }
  box {<-4.5,-6,-0.3>,<4.5,  0,0.3> rotate<-5,0,0>}
  texture{Walltex}}
// --------------- Zusammenbau des Schlosses -----------
// ---------------- zeichne "Turm" an 4 Ecken:.---------
object{ Turm translate<-6, 0,-6>}
object{ Turm translate< 6, 0,-6>}
object{ Turm translate< 6, 0, 6>}
object{ Turm translate<-6, 0, 6>}
// ---------------- zeichne 4 Mauern -------------------
difference{
    object{Mauer} // Mauer mit Torloch --------------
    box{<-1,0,-0.4>,<1,2,0.4>       texture{Walltex}}
    cylinder{<0,2,-0.5>,<0,2,0.5>,1 texture{Walltex}}
                              translate< 0, 0,-6>}
object{Mauer rotate<0,  0, 0> translate< 0, 0, 6>}
object{Mauer rotate<0, 90, 0> translate<-6, 0, 0>}
object{Mauer rotate<0,-90, 0> translate< 6, 0, 0>}
// ------------------- Hof-Boden -----------------------
box {<-6,-4,-6>,< 6,0.01,6>
    texture{pigment{color Gray90}
            finish {diffuse 0.9 phong 1}}}
//-------------------------------------------------end--