Gitarre

Die Konstruktion im Detail:

Die Grundform eines Gitarrenkörpers läßt sich mit einem Prisma (verallgemeinert auch mit krummlinig begrenzter Grundfläche) herstellen, wenn man die Mantelfläche durch eine kubische Spline-Kurve bildet.
Zur Definition eines geeigneten Prismas benötigen wir eine Reihe von Stützpunkten, die auf der Umrißlinie des Gitarrenkörpers liegen. Das Positionieren dieser Stützpunkte ist eine Gefühlssache - d.h. die Methode "Versuch und Irrtum" muß hier zum Einsatz kommen.
Wenn wir den Gitarrenkörpers in der xy-Ebene entwerfen, dann ist dieser Körper symmetrisch zur yz-Ebene. Die spiegelsymmetrisch liegenden Punkte lassen sich am einfachsten über die Definition durch Platzhalter erzeugen, wobei die Koordinaten dieser Spiegelpunkte von den Originalpunkten abhängen.

// ----------- Abmessungen
#declare G_z = 0.15;// Dicke
// Silhuette rechte Seite: 
// ---- -Werte -----
#local S0 = < 0.00, 0.00>;
#local S1 = < 0.16, 0.05>;
#local S2 = < 0.22, 0.20>;
#local S3 = < 0.15, 0.35>;
#local S4 = < 0.17, 0.48>;
#local S5 = < 0.12, 0.56>;
#local S6 = < 0.00, 0.60>;
// 2 dim. Vektoren S(u,v). 
// Hier gilt:  Wenn S(Xs,Yx), 
// dann S.u=Xs u. X.v=Ys.

// automatisches Spiegelbild 
// Silhuette linke Seite:
#local S7 = <-S5.u, S5.v>;
#local S8 = <-S4.u, S4.v>;
#local S9 = <-S3.u, S3.v>; 
#local S10 = <-S2.u, S2.v>; 
#local S11 = <-S1.u, S1.v>; 
//--------------------------
// Lineare Prisma in y-Richtung:
prism { 
   linear_sweep
   cubic_spline
   G_z, 0.00, 15
        
   S0, S1, S2, S3, S4, 
   S5, S6, S7, S8, S9, 
   S10, S11, 
   S0, // letzter = erster 
   S1, // 2 mehr definieren!!!
   S2
   texture { /*nach Belieben!*/}
   rotate<-90,0,0> 
   //dreht Prisma in xy-Ebene!!!
   translate<0.0,0,0> 
} // end of prism ------------

Der Gitarrenkörper: Die Stützpunkte der Silhuettenline wurden durch kleine Kugeln verdeutlicht. Die symmetrisch liegenden Punkte S7 bis S11 sind grün dargestellt.

Klicken Sie hier für die vollständige Beschreibung
dieser Szene für POV-Ray:
".txt"-Datei or ".pov"-Datei

Definiert man obiges Prisma als "Body_Shape", so kann man mit dieser Grundform den Gitarrenkörper darstellen. Verschiedene Texturen an der Front/Rückseite, an den Seitenflächen erhält man, wenn man dieselbe Grundform verschieden skaliert so zusammenaddiert, daß beim der einen Form nur die Frontseite und bei der anderen Form nur die Seitenflächen überstehen. Erst dann wird von diesem Körper der Innenraum und das Schallloch der Gitarre abgezogen.

Das folgende Beispiel soll dies zeigen:

//---- Der Gitarrenköper
difference{
union { // die positiven Teile
 object{Body_Shape
   scale< 1.010,1.010,  0.95>
   translate<0,-0.005*G_y, -0.05*G_z/2>
   texture{G_Texture_outside1} }
object{Body_Shape
   texture{G_Texture_outside  } }
}// Ende der union der
 // positiven Teile des Körpers
        
// Aushöhlen der Innenseite
object{Body_Shape
  scale<0.99,0.99,1-0.01*(1/G_z)>
  translate<0,0.005,-0.005>
  texture{ G_Texture_inside}}
// das Loch
cylinder { <0,0,-0.1>,<0,0,0.1>,G_Hole_R
  translate<0,G_Hole_y,-G_z>
  texture{G_Texture_outside}
  } // end of cylinder  -----------
}// end of difference  ------------
// -- Ende des Gitarrenköpers

Klicken Sie hier für die vollständige Beschreibung
dieser Szene für POV-Ray:
".txt"-Datei or ".pov"-Datei