Descriptions and Samples for the POV-Ray Raytracer by Friedrich A. Lohmüller
     deutsche Version
House with windows overview Castle (1) with 4 towers and a door

Castle: 0.Tower

The Construction of a Tower for the Castle.

Objects: "box", "plane".
Methods: "declare", "union", "difference", "intersection", "inverse", "bounded_by"

Tower in front view.

The Construction in Details:

To construction a tower with a roof there first are added a cylinder with two cones, which form the roof.

tower
Click here for the complete scene description
for POV-Ray: ".txt" file or ".pov" file

//       ............. Tower ...................
union{
 cylinder{<0,0,0>,<0,5,0>,2
      texture{pigment{color rgb<0.4,0,0>}
              finish {ambient 0.15 diffuse 0.85 phong 1}}}
 cone{<0,0,0>,2.5,<0,2.5,0>,0  translate<0,5,0> 
      texture{pigment{color rgb<0.4,0.0,0.0>}
              finish {ambient 0.15 diffuse 0.85 phong 1}}}
 cone{<0,0,0>,1.8,<0,5.5,0>,0  translate<0,5,0>
      texture{pigment{color rgb<0.4,0.0,0.0>}
              finish {ambient 0.15 diffuse 0.85 phong 1}}}
}// end of union ----------------------------------------

To simplify the construction and to make it more flexible to handle it is possible to declare the textures and basic constants variable by "#declare" in the head of the other description.
Now the tower is declared as a new object:

//--------------- dimensions and textures ------------
#declare Walltex = 
  texture{pigment{color White}
          finish {ambient 0.15 diffuse 0.85 phong 1}}
#declare Rooftex =
  texture{pigment{color rgb<0.4,0,0>}
          finish {ambient 0.15 diffuse 0.85 phong 1}}
#declare TR = 2.0;  //TowerRadius 
#declare TH = 5.0;  //TowerHeight   
//-----------------------  Tower  -------------------
#declare Tower =  union{   
cylinder {<0,0,0>,<0,TH,0>,TR 
          texture{Walltex}}
cone{<0,0,0>,TR+0.5,<0,TR+0.5,0>,0
      translate<0,TH,0>   texture{Rooftex}}
cone{<0,0,0>,TR -0.2,<0,2*TR+0.5,0>,0
      translate<0,TH,0>   texture{Rooftex}}
}// ------------------ end of Tower -----------------
// draw "Tower" in 4 angles:
object{ Tower translate<-6, 0,-6>}
object{ Tower translate< 6, 0,-6>}
object{ Tower translate< 6, 0, 6>}
object{ Tower translate<-6, 0, 6>}
//---------------------------------------------------

Click here for the complete scene description
for POV-Ray: ".txt" file or ".pov" file

House with windows overview Castle (1) with 4 towers and a door
© Friedrich Lohmüller, 2003     email email: (legacy email redacted)