Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller
 English   English English version
Haus mit Fenstern Themen Schloss(1) mit 4Türmen und mit Tor

Schloss: 0.Turm

Die Konstruktion eines Schlosses mit Türmen, Tor und Fenstern.

Objekte:    "box", "plane".
Methoden: "declare", "union", "difference", "intersection", "inverse", "bounded_by"

Turm in Vorderansicht.

Die Konstruktion im Detail:

Zur Konstruktion eines Turmes mit Dach wird zunächst auf ein Zylinder zwei verschiedene Kegel gesetzt, welche zusammen das Dach bilden, da sie sich ungestört durchdringen.

tower
Zugehörige Szenenbeschreibung für POV-Ray:
".txt"-Datei oder ".pov"-Datei

//       ............. Turm ..............
union{
 cylinder{<0,0,0>,<0,5,0>,2
  texture{pigment{color White}
          finish{ambient 0.1 diffuse 0.9 phong 1}}}
 cone{<0,0,0>,2.5,<0,2.5,0>,0  translate<0,5,0> 
  texture{pigment{color rgb<0.4,0.0,0.0>}
          finish{ambient 0.1 diffuse 0.9 phong 1}}}
 cone{<0,0,0>,1.8,<0,5.5,0>,0  translate<0,5,0>
  texture{pigment{color rgb<0.4,0,0>}
          finish{ambient 0.1 diffuse 0.9 phong 1}}}
}// end of union -----------------------------------

Vereinfachen und flexibler gestalten läßt sich die Konstruktion dadurch, daß man für Texturen und wesentliche Größen als Variable vorweg mittels "#declare" definiert.
Der Turm wird jetzt auch als neues Objekt definiert:

//-------Größen und Texturen ------
#declare Wandtex = 
  texture{pigment{color White}
          finish {ambient 0.1
                  diffuse 0.9
                  phong 1}}
#declare Dachtex =
  texture{pigment{color rgb<0.4,0,0>}
          finish {ambient 0.1
                  diffuse 0.9
                  phong 1}}
#declare TR = 2.0;  //TurmRadius 
#declare TH = 5.0;  //TurmHöhe   
//------------- Turm  -------------
#declare Turm =  union{   
cylinder {<0,0,0>,<0,TH,0>,TR 
          texture{Wandtex}}
cone{<0,0,0>,TR+0.5,<0,TR+0.5,0>,0
      translate<0,TH,0>
      texture{Dachtex}}
cone{<0,0,0>,TR-0.2,<0,2*TR+0.5,0>,0
      translate<0,TH,0>
      texture{Dachtex}}
}// ----- Ende Turm-Definition ----
// zeichne "Turm" an 4 Ecken:
object{ Turm translate<-6, 0,-6>}
object{ Turm translate< 6, 0,-6>}
object{ Turm translate< 6, 0, 6>}
object{ Turm translate<-6, 0, 6>}
//---------------------------------

Zugehörige Szenenbeschreibung für POV-Ray:
".txt"-Datei oder ".pov"-Datei

Haus mit Fenstern Themen Schloss(1) mit 4Türmen und mit Tor
© Friedrich A. Lohmüller, 2003     email email: (legacy email redacted)