POV-Ray Raytracer Beschreibungen von Friedrich A.Lohmüller

Koordinatensysteme mit Achsen mit POV-Ray

Die Konstruktion von Koordinatensystemen mit Achsen
mit einer gerasterten Ebene aus drei überlagerten Texturen.

Objekte:    "plane, cylinder, cone".
Methoden: "color_map, layered textures, macro"

#macro Axis_( AxisLen, RedTexture,WhiteTexture) 
union{
 cylinder {<0,-AxisLen,0>,<0,AxisLen,0>,0.05
           texture{checker texture{RedTexture  } 
                           texture{WhiteTexture}
                   translate<0.1,0,0.1>}}
 cone{<0,AxisLen,0>,0.2,<0,AxisLen+0.7,0>,0
           texture{RedTexture}}
} // end of union "Axis"                  
#end // of macro Axis (AxisLen)
//--------------------------------------------------
#macro AxisXYZ(AxisLX,AxisLY,AxisLZ,TexRed,TexWhite)
//---- drawing 3 axes --- 3 Achsen zeichnen --------
union{
object{Axis_(AxisLX,TexRed,TexWhite)  
                    rotate< 0,0,-90>}// x-Axis
object{Axis_(AxisLY,TexRed,TexWhite)
                    rotate< 0,0,  0>}// y-Axis
object{Axis_(AxisLZ,TexRed,TexWhite)
                    rotate<90,0,  0>}// z-Axis
} // end of union
#end// of macro "AxisXYZ(...)"  --------------------
//---------drawing the axis ---- Achsen zeichnen -
#declare Tex_Dark =  
texture{pigment{color rgb<1,0.3,0>}
        finish{ambient 0.1 diffuse 0.9 phong 1}}
#declare Tex_White =
texture{pigment{color rgb<1,1,1>}
        finish{ambient 0.1 diffuse 0.9 phong 1}}

object{AxisXYZ(3.5,3,0.0001,Tex_Dark,Tex_White)}
//----------------------- Ende der Koordinatenachsen