POV-Ray Raytracer Beschreibungen von Friedrich A. Lohmüller

Koordinaten-Netz - Gerasterte Ebene

Konstruktion eines gerasterten Ebene als Koordinatennetz
mittels überlagerter Texturen in POV-Ray.

Objekte:    "plane".
Methoden: "color_map, layered textures, macro"

//-------------------<<< Raster macro
#macro Raster(RScale, RLine) 
pigment{
 gradient x scale RScale
 color_map{
  [0.000   color rgbt<0,0,0,0>]
  [0+RLine color rgbt<0,0,0,0>]
  [0+RLine color rgbt<1,1,1,1>]
  [1-RLine color rgbt<1,1,1,1>]
  [1-RLine color rgbt<0,0,0,0>]
  [1.000   color rgbt<0,0,0,0>]
    }}
finish {ambient 0.45
        diffuse 0.55}
#end// of "Raster(RScale, RLine)"
//--------------------<<<< Grid macro
#macro Grid(RasterScale,
            RasterHalfLine,
            Background_pigment)
plane{<0,1,0>,0 
 //layered textures!
 texture{Background_pigment 
         finish{ambient 0.45 
                diffuse 0.65}}
 texture{
  Raster(RasterScale,RasterHalfLine)}
 texture{
  Raster(RasterScale,RasterHalfLine) 
                      rotate<0,90,0>}
  }// end of plane
#end // end of "Grid(...)"-macro ----
// use it: 
object{ Grid(0.50,0.035,  
        pigment{
           color rgb<1,1,1>*1.1})}
//--------------------------- end ---