Hausbau Teil 2

#declare Wall_Texture_1 = 
texture{ pigment{color rgb<1,1,1>*1.1}
         normal {bumps 0.5 scale 0.005} 
         finish {ambient 0.15 diffuse 0.85}
       } // end of texture
#declare Wall_Texture_2 = 
texture{ pigment{color  rgb<1,1,1>*1.1}
         finish {ambient 0.15 diffuse 0.85}
        } // end of texture
//-------------------------------------------

#declare Wd = 0.20 ; // Wanddicke

// Das Aushöhlen des Hauskörpers
difference{ //-------------------------------
box { <-Hx,0,0>,< Hx,Hy,Hz>   
      texture { Wall_Texture_1} 
    } // end of box -------------------------
plane{ <0,-1,0>,0 
       texture { Wall_Texture_2} 
       rotate<0,0,Roof_Angle>
       translate<0,Hy,0>
     } // end of plane ----------------------
plane{ <0,-1,0>,0 
       texture { Wall_Texture_2} 
       rotate<0,0,-Roof_Angle>
       translate<0,Hy,0>
     } // end of plane ---------------------- 
 // inside caved out  - Innenraum ausgehölt  
box { <-Hx+Wd,0.10,Wd>,<Hx-Wd,Hy,Hz-Wd>  
      texture {Wall_Texture_2}  
     }
}// end of difference -----------------------

#declare Roof_Texture =  // ------- Dach-Textur
// layered textures !!!  - überlagerte Texturen
texture{ pigment{color rgb<0.55,0.09,0.09>*1.3}
         normal {gradient z scallop_wave 
                             scale<1,1,0.15>}
         finish {ambient 0.15 diffuse 0.85}
       } // end of texture
 
texture{ pigment{ gradient x 
                  color_map{
                  [0.00 color rgbt<1,1,1,1>]
                  [0.90 color rgbt<1,1,1,1>]
                  [0.95 color rgb<1,1,1>*0.1]
                  [1.00 color rgb<1,1,1>*0.1]}
                  scale 0.25}
          finish {ambient 0.15 diffuse 0.85}
       } // end of texture
//---------------------------- Ende Dach-Textur
#declare Roof_D = 0.10; // Dachdicke
#declare Roof_O = 0.20; // überhang 
#declare Roof_L = Hx+0.80;// ausprobieren ! 

// Die Dachflächen auf dem Hauskörper
box{  // linke Dachfläche
 <-Roof_L,0,-Roof_O>,<Roof_D/2,Roof_D,Hz+Roof_O>  
 texture {Roof_Texture translate<-0.05,0,0>}  
 rotate<0,0, Roof_Angle>
 translate<0,Hy,0>
}
box{ // rechte Dachfläche 
 <-Roof_L,0,-Roof_O>,<Roof_D/2,Roof_D,Hz+Roof_O>  
 texture {Roof_Texture translate<-0.05,0,0>}  
 rotate<0,0, Roof_Angle>
 translate<0,Hy,0> 
 scale<-1,1,1> // gespiegelt in x-Richtung!!!
}
//--------------------------------------- Ende Dach