Hausbau Teil 3

Die Konstruktion eines Hauses (Fenstern und Türe)

Objekte: "box", "plane".
Methoden: "declare", "union", "difference"

Der Einbau von Fenstern:

Zur Konstruktion der Fenster vgl. Fenster.
(Eine Türe wird analog konstruiert!)
Um aus den Hauswänden die Löcher für die Fenster und die Türe möglichst rationell auszuschneiden, werden zusammen mit den Fenstern bzw. der Türe Löcher definiert. Diese Körper werden über die Inversenbildung in der Schnittmenge der Hauswand zusammen mit dem inneren Kern und den Dachschrägen abgezogen.
An den selben Positionen werden danach die Fenster und die Türe zum Wandkörper des Hauses durch "union" hinzu addiert.
Für eine rationelle Plazierung der Fenster und Türen empfiehlt es sich die Fenster- und Türpositionen als Variable vorweg zu definieren! Dadurch wirken sich &Auuml;nderungen in einer Fensterposition sofort sowohl auf das Fensterloch wie auch auf das zugehörige Fenster aus!


// ------------ Die Fensterpositionen -----------
// front positions 
#declare Window_Positon_1=<-Hx/2,0,Wall_D/3>;
#declare Window_Positon_2=< Hx/2,0,Wall_D/3>;
// right side positions
#declare Window_Positon_3=< Hx-Wall_D/3,0,3*Hz/4>;
#declare Window_Positon_4=< Hx-Wall_D/3,0,  Hz/4>;
//-----------------------------------------------
#declare Window = 
union{
 difference{
  box{<-0.50,0.80,-0.02>,< 0.50,1.80,0.02>}
  box{<-0.45,0.85,-0.03>,<-0.03,1.27,0.03>}
  box{< 0.03,0.85,-0.03>,< 0.45,1.27,0.03>}
  box{<-0.45,1.33,-0.03>,< 0.03,1.75,0.03>}
  box{< 0.03,1.33,-0.03>,< 0.45,1.75,0.03>}
  texture{Windtex1}
  } // ---end of difference 
 box{<-0.49,0.81,0.0>,< 0.49,1.79,0.001>
 texture{T_Glass3}}
 } // --- end of union -------------------

#declare Window_Hole =   //symmetric!!!
  box{<-0.50,0.80,-0.50>,< 0.50,1.80,0.50>
      texture{Windtex2} 
    } // end of box -----------------------
//--------- end of window definition ------

// Fensterloch im Hauskörper
difference{ //-----------------------------
box { <-Hx,0,0>,< Hx,Hy,Hz>   
      texture { Wall_Texture_1} 
    } // end of box -----------------------
plane{ <0,-1,0>,0 
       texture { Wall_Texture_2} 
       rotate<0,0,Roof_Angle>
       translate<0,Hy,0>
     } // end of plane --------------------
plane{ <0,-1,0>,0 
       texture { Wall_Texture_2} 
       rotate<0,0,-Roof_Angle>
       translate<0,Hy,0>
     } // end of plane -------------------- 
 // inside caved out  - Innenraum ausgehölt  
box { <-Hx+Wd,0.10,Wd>,<Hx-Wd,Hy,Hz-Wd>  
      texture {Wall_Texture_2}  
     } // end of box ----------------------
 // window holes caved out
object{Window_Hole translate Window_Positon_1}
object{Window_Hole translate Window_Positon_2}
object{Window_Hole translate Window_Positon_3}
object{Window_Hole translate Window_Positon_4}

}// end of difference ----------------------

 // Adding the windows: 
object{Window   translate Window_Positon_1}
object{Window   translate Window_Positon_2}
object{Window rotate<0,90,0> translate Window_Positon_3}
object{Window rotate<0,90,0> translate Window_Positon_4}
//--------------------------------------------------