Descriptions and Samples for the POV-Ray Raytracer by Friedrich A. Lohmüller

A Wheel - with and without #while Statement

Sample for the using of "#while"

Objects: "torus", "cylinder"
Methods: "declare", "union", "#while"

...
#declare Number_of_spokes = 16; 
#declare W = 360/Number_of_spokes;  
//-------------------------------------------------- wheel
union{
torus{0.9,0.20 scale <1,1,1> rotate<90,0,0>
         texture{Rimtex}} // rim
torus{1.0,0.25 scale <1,1,1> rotate<90,0,0>
         texture{Tiretex}} // tire
cylinder {<0,0,-0.48>,<0,0, 0.48>,0.05
         texture{Hubtex}} // hub
//------------------- without #while-Schleife: --------<<1

union{
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 0*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 1*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 2*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 3*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 4*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 5*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 6*W>}
 cylinder {<-1,0, 0>,<1,0, 0>,0.05 rotate<0,0, 7*W>}
 texture{Rimtex}}

//---------------------------------------------- end --<<2
translate<0,1.25,0> rotate<0,40,0>} // end of union 
//---------------------------------------------- end ----

...
//or from <<1  until <<2 --- with while-loop ----->>1
#declare Nr = 0;  
#declare EndNr = Number_of_spokes/2;

#while ( Nr < EndNr )
  cylinder {< -1, 0, 0>,< 1, 0, 0>, 0.05
            rotate< 0, 0, 180/EndNr * Nr >
            texture{Rimtex}}
  #declare Nr = Nr +1;
#end // ------------------------------------------>>2
...