Descriptions and Examples for the POV-Ray Raytracer by Friedrich A. Lohmüller
Design of Surfaces by "texture" with POV-Ray -
Deutsch Deutsch
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  Design of Surfaces
  - Colors and Textures
    Index

    texture Syntax
    Ready-made Textures
    Do-it-yourself Colors
    Patterns
    Patterns Lists
    Warps
    uv_mapping
    Mapping
    Superpositions
   > Layered Textures
      squared paper grid

    Your own Textures
 
                                           

Layered Textures

Layers of Partly Tansparent Patterns

We can layer over a basic texture a second or more partly transparent textures! The last defined texture will be seen a the top of the surface and where this texture is transparent we can see the lower texture layers.


Example 1: "Layered Textures":


Sample layered textures 640x480

sphere{ <0,0,0>,1
        scale <1.2,1,1>
        translate<0,1.3,0>
        texture{ Polished_Chrome
               } // end of texture #1
        texture{ Peel scale 0.5 translate<2,0,0>
                 normal  { wrinkles 0.75 scale 0.1}
                 finish  { diffuse 0.9 phong 0.3}
               } // end of texture #2 obendrauf
       } // end of sphere

Example 2: "Layered Textures":


Sample layered textures 640x480

#declare Textur1 = //--------------------  texture 1
texture{
  pigment{ ripples scale 0.5 turbulence 0.75
    color_map { [0.0 color Green]
                [0.4 color Yellow]
                [0.4 color White]
                [1.0 color YellowGreen]
              } // end of color_map
          } // end of pigment
  normal { wrinkles 0.75 scale 0.1}
  finish { diffuse 0.65
          reflection 0.25 phong 1}
} //------------------------------ end of texture 1
#declare Textur2 = //-------------------  texture 2
texture{
  pigment{gradient<0,1,0> scale 0.5 turbulence 1.25
    color_map { [0.0 color Clear]
                [0.7 color Clear]
                [0.7 color rgb<1,0.75,0> ]
                [1.0 color Gray50 ]
                 } // end of color_map
        } // end of pigment
 normal { ripples 0.8 scale 0.02 turbulence 0.5 }
 finish { diffuse 0.9 phong 1}
 } //----------------------------- end of texture 2
//-------------------------------------------------
sphere{<0,0,0>,1 scale <1.2,1,1>
      texture{Textur1}
      texture{Textur2}
      translate<0,1,0>
      } // end of sphere --------------------------

top

© Friedrich A. Lohmüller, 2006
http://www.f-lohmueller.de