Acceleration in accordance
with physical Formulas
Non-linear movements in animations
to simulate realistic acceleration or deceleration by
physical laws of Motion with POV-Ray.

The Laws of Motion
  for some simple types of motions
( t = time, s = distance, v = velocity, a = acceleration )
1. Motion with constant speed v:

Velocity	v = constant
Covered distance	s(t) = v * t

//---------------------------------------------------
#declare Total_Time = 4.48;
#declare Time = Total_Time*clock; //

#declare Time_A  = 2.65; // start acceleration
#declare Time_B  = 3.45; //   end acceleration
// total acceleration time:
#declare Ac_Time = Time_B-Time_A;
// last sector without acceleration:
#declare End_Time= Total_Time-Time_B;

#declare Acceleration =   5.0 ;
// v(0) = constant speed at start:
#declare V_0          =     1 ;

// final speed after acceleration
#declare End_Speed  = 

    Acceleration * Ac_Time + V_0 ;

// covered distances
//1: with constant speed:
#declare Way1 = V_0*Time_A ;
//2: with constant acceleration
#declare Way2 =
   Acceleration/2*pow(Ac_Time,2)+V_0*Ac_Time+Way1;
   //note: pow(Ac_Time,2) = Ac_Time*Ac_Time

// with constant speed in last sector
//3: total distance
// --- distance totale
#declare Way3 =  End_Speed*(  End_Time ) + Way2 ;
//---------------------------------------------------

//---------------------------------------------------
// calculating the distance at 'Time'
// --- calulation de la distance au temps 'Time'
// covered by the rolling sphere;
// --- parcourue de la sphère roulante:

 // constant translation
 #if ( Time < Time_A )
   #declare Way = V_0*Time;
 #end
 // constant translation + acceleration
 #if (( Time >= Time_A ) & ( Time < Time_B ))
   #declare Way = Acceleration/2*pow(Time - Time_A,2)
                  + V_0*(Time - Time_A) + Way1;
 #end
 // way with constant speed after acceleration ends
 #if ( Time >= Time_B )
   #declare Way = End_Speed*( Time - Time_B) + Way2;
 #end
//---------------------------------------------------
 sphere{<0,0,0>,0.75  translate<0,0.75, Way>}
//---------------------------------------------------