Spherical Environment Mapping
Skydome con immagini panoramiche a 360°:

Un skydome (duomo di cielo) è una semisfera grande o una sfera (se vogliamo simulare lo spazio) con una immagine panoramica a 360° di un cielo ("skymap") proiettata ("mapped") su l'interno di questa semisfera o sfera.
Questo si può realizzare in POV-Ray con image_map e sky_sphere.

Per usare una foto panoramica a 360° o un immagine come skymap in un skydome (con POV-Ray 3.6/3.7) abbiamo bisogno di correggere il fattore gamma dell'immagine o foto con la macro seguente.

// Macro per la correzione di immagini
// per image_map con assumed_gamma = 1.0 ;
#macro Correct_Pigment_Gamma(Orig_Pig, New_G)
  #local Correct_Pig_fn =
      function{ pigment {Orig_Pig} }
  pigment{ average pigment_map{
   [function{ pow(Correct_Pig_fn(x,y,z).x, New_G)}
               color_map{[0 rgb 0][1 rgb<3,0,0>]}]
   [function{ pow(Correct_Pig_fn(x,y,z).y, New_G)}
               color_map{[0 rgb 0][1 rgb<0,3,0>]}]
   [function{ pow(Correct_Pig_fn(x,y,z).z, New_G)}
               color_map{[0 rgb 0][1 rgb<0,0,3>]}]
   }}
#end //
// "image_map" gamma corrected:
//    Correct_Pigment_Gamma(
//    pigment{ image_map{ jpeg "colors.jpg"}}
//    , Correct_Gamma)
//------------------------------------------------
sky_sphere{
   Correct_Pigment_Gamma( // gamma correction
     pigment{
     image_map{ jpeg "sky_map_p_04_5200x1300.jpg"
                map_type 2    //  cylindrical
                interpolate 2 //  bilinear
                once //
              } //  end of image_map
      scale<1,1.02,1> rotate<0,0.00,0>
    } // end of pigment
    , 2.2) //, New_Gamma
} // end of sky_sphere --------------------

Molte foto panoramiche a 360° si trovano qui:
Free high res skymaps di M@dcow a Blender Artists Forums (en).

Una immagine panoramica a 360° di un cielo proiettata in modo cilindrico su una sfera.
Una veduta a 180° verso lo zenit di cielo.
Esempio di scena con skymap proiettata su sky_sphere.
Descrizione di questa scena per POV-Ray
Test_sky_map_p_04_5200x1300.txt o
Test_sky_map_p_04_5200x1300.pov

Una immagine panoramica a 360° come skymap proiettata su sky_sphere in POV-Ray.
Download di questo skymap (5200x1300 pixel, 1.1 MB) qui: sky_map_p_04_5200x1300.jpg

contenuto | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10