Spherical Environment Mapping -
La projection sphérique de l'environnement
Skydomes et Skymaps avec des images de panorama à 360°.

Un skydome est une hémisphère ou sphère (si nous voulons simuler l'espace) avec une texture d'un image de panorama à 360° du ciel ("skymap") projetée ("mapped") sur la face interne de cette hémisphère ou sphère. Nous pouvons réaliser cela en POV-Ray avec image_map et sky_sphere.

Pour utiliser un photo de panorama à 360° pour une skymap dans un skydome (avec POV-Ray 3.6/3.7) nous avons besoin de corriger le gamma de l'image ou photo avec la macro suivante.

// Macro pour corriger les images
// pour image_map avec assumed_gamma = 1.0 ;
#macro Correct_Pigment_Gamma(Orig_Pig, New_G)
  #local Correct_Pig_fn =
      function{ pigment {Orig_Pig} }
  pigment{ average pigment_map{
   [function{ pow(Correct_Pig_fn(x,y,z).x, New_G)}
               color_map{[0 rgb 0][1 rgb<3,0,0>]}]
   [function{ pow(Correct_Pig_fn(x,y,z).y, New_G)}
               color_map{[0 rgb 0][1 rgb<0,3,0>]}]
   [function{ pow(Correct_Pig_fn(x,y,z).z, New_G)}
               color_map{[0 rgb 0][1 rgb<0,0,3>]}]
   }}
#end //
// "image_map" avec gamma corrigé:
//    Correct_Pigment_Gamma(
//    pigment{ image_map{ jpeg "colors.jpg"}}
//    , Correct_Gamma)
//------------------------------------------------
sky_sphere{
   Correct_Pigment_Gamma( // gamma correction
     pigment{
     image_map{ jpeg "sky_map_p_04_5200x1300.jpg"
                map_type 2    //  cylindrical
                interpolate 2 //  bilinear
                once //
              } //  end of image_map
      scale<1,1.02,1> rotate<0,0.00,0>
    } // end of pigment
    , 2.2) //, New_Gamma
} // end of sky_sphere --------------------

On peut trouver plus des photos de panorama à 360° de ciels ici :
Free high res skymaps de M@dcow aux Blender Artists Forums (en).

Un image à 360° cylindriquement "mapped" sur une sphère.
Une vue à 180° au zénith du ciel.
Un scène d'exemple avec skymap "mapped" sur la sky_sphere.
Description de cette scène pour POV-Ray
Test_sky_map_p_04_5200x1300.txt ou
Test_sky_map_p_04_5200x1300.pov

Un image de panorama à 360° d'un ciel pour une skymap sur la sky_sphere en POV-Ray.
Téléchargement de cette skymap en 5200x1300 pixel (1.1 MB) ici: sky_map_p_04_5200x1300.jpg

Contenu | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10