Descrizioni et esempi per il raytracer POV-Ray di Friedrich A. Lohmüller
 English English English
Français français
Deutsch Deutsch
macro "Segment_of_CylinderRing (...)" overview my macro objects macro "Segment_of_Object (...)"

Quest'oggetto è definito con una macro nel mio include file "shapes_lo.inc":

Torus_Segment

Segment_of_Torus
un segmento di toro

 Segment_of_Torus = segmento di toro
 
Sintassi generale: 
object{ Segment_of_Torus (R_major, R_minor, Segment_Angle)
        texture{ ... ... }
      } // end of object ------------
Con:
R_major = il raggio majore del toro,
R_minor = il raggio minore del toro,
Segment_Angle = l'angolo delo segmento del toro.

Per raggioni di compatibilità il macro vecchio "Torus_Segment"
esiste ancora - lá l'angolo è stato orientato in senso di mano destra!
Esempi: 
#include "shapes_lo.inc"
object{ Segment_of_Torus( 1.00, 0.25, -145)
        texture { pigment{color rgb<1,0.7,0>}
                  finish {ambient 0.15 diffuse 0.85 phong 1}
                } // end of texture
        rotate<-90,0,0> translate<0,1,0>
      } // end of Segment_of_Torus(...) -----------------------


object{ Segment_of_Torus ( 0.60, 0.25, -275)
        texture { pigment{color rgb<1,0.4,0>}
                  finish {ambient 0.15 diffuse 0.85 phong 1}
                } // end of texture
        rotate<0,30,0> translate<0.5,0.3,-0.5>
      } // end of Segment_of_Torus(...) -----------------------

object{ Segment_of_Torus ( 0.60, 0.50, -60)
        texture { pigment{color rgb<1,0.2,0>}
                  finish {ambient 0.15 diffuse 0.85 phong 1}
                } // end of texture
        rotate<-90,0,-190> translate<0,1,0>
      } // end of Segment_of_Torus(...) -----------------------

La macro nel dettaglio

Per questo consideriamio due casi:
1. abs(Segment_Angle) <= 180 gradi (solo un'intersezione di un toro e due scatole) e
2. abs(Segment_Angle) > 180 gradi (un'intersezione di un toro e l'unione di due scatole): 
//--------------------------------------------------------Segment_of_Torus
#macro Segment_of_Torus ( R_major, R_minor, Segment_Angle)
//---------------------------------------------------------------------------
#local D =  0.00001;
 #if (Segment_Angle < 0)
      #local Negativ_Flag = 1;
      #local Segment_Angle = -Segment_Angle;
 #else
      #local Negativ_Flag = 0;
 #end
 #if (Segment_Angle > 360) #local Segment_Angle = mod(Segment_Angle,360); #end

intersection{
 torus { R_major, R_minor }

#if (Segment_Angle > 180)
 union{
#end // use union!

 box   { <-1,-1,0>,<1,1,1>
         scale < R_major+R_minor+D, R_minor+D, R_major+R_minor+D>
       }// end of box
 box   { <-1,-1,-1>,<1,1,0>
         scale < R_major+R_minor+D, R_minor+D, R_major+R_minor+D>
         rotate < 0,-Segment_Angle,0 >
       }// end of box

#if (Segment_Angle > 180)
 }
#end // end of union, if union is used!

 #if (Negativ_Flag = 0)  rotate<0, Segment_Angle,0>   #end

 } // end of intersection
#end  // -------------------------- end of macro Segment_of_Torus

Le immagini seguenti mostrano come lavora questa macro
(i box sono visualizati in testura "glass"):
 
Segment_of_Torus Segment_of_Torus
abs(Segment_Angle) <= 180 degrees
R_major = 1.00, R_minor = 0.25, Angle = -145 		abs(Segment_Angle) > 180 degrees
R_major = 1.00, R_minor = 0.25, Angle = -215





macro "Segment_of_CylinderRing (...)" overview my macro objects macro "Segment_of_Object (...)"
© Friedrich A. Lohmüller, 2009
email email: (legacy email redacted)
homepage:www.f-lohmueller.de