Schloss: 1.Schloss mit 4 Türmen und Tor

//-----------------------------------------------------
#declare Wandtex = 
 texture{pigment{color White}
         finish {ambient 0.1 diffuse 0.9 phong 1}}
#declare Dachtex =
  texture{pigment{color rgb<0.4,0,0>}
          finish {ambient 0.1 diffuse 0.9 phong 1}}
#declare TR =  2.0;   //TurmRadius
#declare TH =  5.0;   //TurmHöhe
//-----------------------  Turm  ----------------------
#declare Turm =  union{     //definiert Objekt "Turm"
cylinder {<0,0,0>,<0,TH,0>,TR    texture{Wandtex}}
cone{<0,0,0>,TR+0.5,<0,TR+0.5,0>,0
                    translate<0,TH,0> texture{Dachtex}}
cone{<0,0,0>,TR -0.2,<0,2*TR+0.5,0>,0
                    translate<0,TH,0> texture{Dachtex}}
}// ------------------ Ende Turm-Definition -----------
// zeichne "Turm" an 4 Ecken:
object{ Turm translate<-6, 0,-6>}
object{ Turm translate< 6, 0,-6>}
object{ Turm translate< 6, 0, 6>}
object{ Turm translate<-6, 0, 6>}
//-----------------------------------------------------
//------------------------ Mauer ----------------------
#declare Mauer =
box {<-4,0,-0.3>,< 4,3.5,0.3>      texture{Wandtex}}
// ---------------- zeichne 4 Mauern ------------------
difference{
   object{Mauer} // Mauer mit Torloch --------------
   box{<-1,0,-0.4>,<1,2,0.4>       texture{Wandtex}}
   cylinder{<0,2,-0.5>,<0,2,0.5>,1 texture{Wandtex}}
                             translate< 0, 0,-6>}
object{Mauer rotate<0,  0, 0> translate< 0, 0, 6>}
object{Mauer rotate<0, 90, 0> translate<-6, 0, 0>}
object{Mauer rotate<0,-90, 0> translate< 6, 0, 0>}
// ------------------- Hof-Boden ----------------------
box {<-6,-4,-6>,< 6,0.01,6>
     texture{pigment{color Gray90}
             finish {ambient 0.1 diffuse 0.9 phong 1}}}
//------------------------------------------------end--