Descriptions and Examples for the POV-Ray Raytracer by Friedrich A. Lohmüller
logo
    3D Animations with POV-Ray
        Some basics and examples on animations.
Italiano Italiano
Français français
Deutsch Deutsch
Home
- 3D Animations Gallery
- POV-Ray Tutorial

  3D Animation Tutorial
   Index of Content
  0. Basic Knowledge
     1. Basic Example
     2. Example 2
     3. Images to Animated Gif
     4. From Images to Video
     5. Basic Terms
     6. Animation Commands  
  I. Cyclic Animations
     1. Rotating Objects
     1.2. Planets in Orbit
     1.3. Clock Animation
     2. Rotating Camera
     2.1. Straight Moving Camera
     3. Western Wheel
         Problem
     3.1. Rolling Wheels
     4. Gears
     4.1. Roller Chain
     4.2. Bike Chain
     5. Swinging Pendulum
     5.1: Newton's Cradle
  > 5.2. Rock the Rocker
     6. Spiral Pendulum
     7. Coupling Rods
     7.1. Connecting Rods
     8. Psychedelic + Op-Art
     9. Counters + Countdowns
    10. Folding of a Cube
  II. Non-linear Movements
     1.0 Speed Up/Slow Down 1
     1.1 Speed Up/Slow Down 2
     2. Fall + Bounce
     3. Acceleration by
          physical Formulas
     4. Speed Controll by
          Spline Functions
  III. Animation Paths
      with Spline Curves
     1. Spline Curves
     2. Closed Splines
     3. Animation Paths
                                                       
     
Rock the Rocker!
A Rocking Chair rolling in a sinus rhythm.
     

A Rocking Chair in Action
At first sight a rocking rocker seams to be something like a swinging Pendulum.
But if you look more thoroughly, we can recognize that this is more like a rolling wheel, which rolls forward and backward and this in a sinus rhythm.

Here a simplified Rocker reduced to a single skid as a macro object.
For the complete Rocker object see the scene file below!
#macro Rocker0( Rocking_Angle )
//---------------------------------
#local D = 0.00001; // just a little bit!
#local R_R = 1.20; // rocker skids radius
#local R_rotate = 25; // skids angle +/-
#local D_feet = 0.055;
//---------------------------------------
#local Skid =
 intersection{
   box{<-R_R,-R_R-D,-D_feet/2-2*D>,
       <0,R_R+D,D_feet/2+2*D>
       rotate<0,0,-R_rotate>
       inverse }
   box{<-R_R,-R_R-D,-D_feet/2-2*D>,
       <0,R_R+D,D_feet/2+2*D>
       rotate<0,0,-R_rotate>
       inverse
       scale<-1,1,1> }
   cylinder{<0,0,-D_feet/2>,
            <0,0,D_feet/2>, R_R}
   cylinder{<0,0,-D_feet/2-D>,
            <0,0,D_feet/2+D>, R_R-D_feet
            inverse }
 } // end intersection Skid
//---------------------------------------

object{ Skid
  rotate< 0,0,Rocking_Angle>
  translate< 0, R_R, 0>
// move by the
// according part of the circumference:
  translate
  <-(2*pi*R_R)*(Rocking_Angle/360),0,0>
} // end of Skid
#end // end of macro Rocker0() ----------

Rocking Chair
    A Rocking Chair in Action
Rocking Chair
          How to rock a rocking chair.



Rocker0
The rocking skid of 'Rocker0' example.
And here how to use this macro Rocker0():
#declare Time =  clock + 0.00;
//---------------------------------------
object{
  Rocker0( 12* sin(Time*2*pi) )
    texture{
      pigment{ color rgb<0.2,0.12,0.08>}
      finish { phong 1 reflection 0}
    } // end of texture
    rotate<0,0,0>
    translate<0,0,0>
} // end of Rocker0 ---------------------
Scene files for the above skid demo in POV-Ray:
"Rocker0.ini" and "Rocker0.pov"
Rocking Chair
      Rocking Chair 'Rocker_01'

    Scene files for a complete
    rocking chair in POV-Ray:
"Rocker_01.ini" and "Rocker_01.pov"
Bigger animations of rocking chairs
you'll find in my Gallery of 3D Animations - Oszillations
.

top
© Friedrich A. Lohmüller, 2012
http://www.f-lohmueller.de