Spherical Environment Mapping
Himmel mittels Skydomes und 360°-Panoramabildern:

Ein Skydome ist eine große Halbkugel oder Kugel (wenn wir Weltraum simulieren wollen) mit einem 360°-Panoramabild des Himmels ("skymap") aufgemapped auf der Innenseite dieser Kugel/Halbkugel. Dies ist eine der "environment mapping" genannten Projektionstechniken.
Dies kann man POV-Ray mittels image_map und sky_sphere realisieren.

Zur Verwendung von einem 360°-Panoramafoto oder -Bild als eine Skymap in einen Skydome (mit POV-Ray 3.6/3.7) müssen wir den Gammawert des Bildes/Fotos mittels folgendem Makro korrigieren.

// Makro zur Anpassung von Bildern
// für image_map mit assumed_gamma = 1.0 ;
#macro Correct_Pigment_Gamma(Orig_Pig, New_G)
  #local Correct_Pig_fn =
      function{ pigment {Orig_Pig} }
  pigment{ average pigment_map{
   [function{ pow(Correct_Pig_fn(x,y,z).x, New_G)}
               color_map{[0 rgb 0][1 rgb<3,0,0>]}]
   [function{ pow(Correct_Pig_fn(x,y,z).y, New_G)}
               color_map{[0 rgb 0][1 rgb<0,3,0>]}]
   [function{ pow(Correct_Pig_fn(x,y,z).z, New_G)}
               color_map{[0 rgb 0][1 rgb<0,0,3>]}]
   }}
#end //
// "image_map" Gamma korregiert:
//    Correct_Pigment_Gamma(
//    pigment{ image_map{ jpeg "colors.jpg"}}
//    , Correct_Gamma)
//------------------------------------------------
sky_sphere{
   Correct_Pigment_Gamma( // gamma correction
     pigment{
     image_map{ jpeg "sky_map_p_04_5200x1300.jpg"
                map_type 2    //  cylindrical
                interpolate 2 //  bilinear
                once //
              } //  end of image_map
      scale<1,1.02,1> rotate<0,0.00,0>
    } // end of pigment
    , 2.2) //, New_Gamma
} // end of sky_sphere --------------------

Hier kann man weitere Panorama-Bilder von Himmeln finden: Free high res skymaps von M@dcow im Blender Artists Forums (en).

Ein 360°-Bild zylindrisch auf eine Kugel gemapped.
Ein 180°-Blick in den Zenit des Himmels.
Beispielszene mit Skymap auf der sky_sphere.
Beschreibung dieser Szene für POV-Ray
Test_sky_map_p_04_5200x1300.txt oder
Test_sky_map_p_04_5200x1300.pov

Ein 360°-Panoramabild als Skymap für die sky_sphere in POV-Ray.
Download von dieser Skymap in 5200x1300 pixel (1.1 MB) hier: sky_map_p_04_5200x1300.jpg

Inhalt | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10