Descriptions and Examples for the POV-Ray Raytracer by Friedrich A. Lohmüller
Design of Surfaces by "texture" with POV-Ray -
Deutsch Deutsch
Italiano Italiano
Français français

Home
- POV-Ray Tutorial

  Design of Surfaces
  - Colors and Textures
    Index

    texture Syntax
    Ready-made Textures
    Do-it-yourself Colors
    Patterns
    Patterns Lists
    Warps
    uv_mapping
    Mapping
    - Mapping Methods
    - color_map{ ... }
    - pigment_map{ ... }
    - texture_map{ ... }
    - normal_map{ ... }
    - average
    - material_map{ ... }
    - image_map{...}
    - image_map+gif 1
    - image_map+gif 2
   > image_map+gamma
    - bump_map{ ... }
    - transparency maps 1
    - transparency maps 2
    - transparency maps 3
    Superpositions

    Your own Textures
 
                                             
"image_map{ ... }" and "gamma"
 A feature for image_map images, new in POV-Ray version 3.7

There are big differences between POV-Ray version 3.6.2 and version 3.7
in the handling the gamma of images used in image_map:

"image_map" with POV-Ray 3.6.2:
//--------------------------------------
#version 3.6;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9}}
//--------------------------------------
// ...
// box with layered textures
box { <-0.04,-0.04,0>,< 1.03, 1.04, 0.01>
      // 1st layer: White
      texture{
        pigment{ color rgb<1,1,1>*1.1 }
        finish{ phong 1}
      } // ------------------------------
      // 2nd layer: image_map
      texture{
        pigment{
          image_map{
          jpeg "Image_gamma_0.jpg"
          map_type 0
          interpolate 2
          once
         } // end of image_map
       } //  end of pigment
     } // end of texture

     scale <4/3,1,1>*1.75
     translate<-1.5,0.1,-2>
} // end of box //-----------------------
A macro for the adjustment of image gamma
in image_maps with POV-Ray version 3.6.2. is here.
image for image_map
The image used here for image_map
Image file: Image_gamma_0.jpg

image_map with POV-Ray 3.6
image_map with POV-Ray 3.6 ... a gamma problem!
POV-Ray 3.6.2 scene file: Image_gamma36_1.pov
"image_map" with POV-Ray 3.7 (RC6):
//--------------------------------------
#version 3.7;
global_settings{ assumed_gamma 1.0 }
#default{ finish{ ambient 0.1 diffuse 0.9}}
//--------------------------------------
// ...
// box with layered textures
box { < -0.04, -0.04,0>,< 1.03, 1.04, 0.01>
      // 1st layer: White
      texture{
        pigment{ color rgb<1,1,1>*1.1 }
        finish{ phong 1}
      } // ------------------------------
      // 2nd layer: image_map
      texture{
        pigment{
          image_map{
          jpeg "Image_gamma_0.jpg"
          map_type 0
          interpolate 2
          once
         } // end of image_map
       } //  end of pigment
     } // end of texture

     scale <4/3,1,1>*1.75
     translate<-1.5,0.1,-2>
} // end of box //-----------------------
   






image_map with POV-Ray 3.6
image_map with POV-Ray 3.7, default gamma handling
POV-Ray 3.7 scene file: Image_gamma37_1.pov
"image_map" in POV-Ray 3.7 (RC6)
with gamma correction of image input:
We can overwrite the default gamma handling!

// box with layered textures
box { < -0.04, -0.04,0>,< 1.03, 1.04, 0.01>
      // 1st layer: White
      texture{
        pigment{ color rgb<1,1,1>*1.1 }
        finish{ phong 1}
      } // ------------------------------
      // 2nd layer: image_map
      texture{
        pigment{
          image_map{
          jpeg "Image_gamma_0.jpg"
          gamma 2.0
          map_type 0
          interpolate 2
          once
         } // end of image_map
       } //  end of pigment
     } // end of texture
     scale <4/3,1,1>*1.75
     translate<-1.5,0.1,-2>
} // end of box //-----------------------
   

image_map with POV-Ray 3.6
image_map with POV-Ray 3.7 and 'gamma 2.0'

"image_map" with POV-Ray 3.7 (RC6)
with gamma correction + emission:

// box with layered textures
box { < -0.04, -0.04,0>,< 1.03, 1.04, 0.01>
      // 1st layer: White
      texture{
        pigment{ color rgb<1,1,1>*1.1 }
        finish{ phong 1}
      } // ------------------------------
      // 2nd layer: image_map
      texture{
        pigment{
          image_map{
          jpeg "Image_gamma_0.jpg"
          gamma 2.5
          map_type 0
          interpolate 2
          once
         } // end of image_map
       } //  end of pigment
       finish{ emission 0.3 }
     } // end of texture
     scale <4/3,1,1>*1.75
     translate<-1.5,0.1,-2>
} // end of box //-----------------------
   

image_map with POV-Ray 3.6
image_map with POV-Ray 3.7
and 'gamma 2.5' + 'emission 0.3'
top

© Friedrich A. Lohmüller, 2012
http://www.f-lohmueller.de