How to create realistic skies with POV-Ray

Shadow casting clouds:

To get this effect the sun must be placed between the highest transparent cloud level and the plane with the blue sky texture.
To make it easier to place the sun precisely in a space between the clouds you can use a sphere with a mirror texture and a phong (to make visible the position of the sun) like i.e. "Polished_Chrome".

Sky with clouds casting shadows on the ground.
Click on the image for a higher resolution!
Description of this scenery for POV-Ray

Shadow casting clouds
A solution of the horizon problem without fog.
Here we split the sky into two parts:
1: A sky_sphere with a gradient from white to blue.
2: A gigantic sphere with a transparent cloud pattern. Because of the big radius it appears nearly as a plane and clouds become smaller near the horizon.
With this solution we don't need to keep the light_source for our sun below the clouds level. But we have to move the sun or the clouds if the shadow of the clouds hits parts of our scene which we want to be in full sunlight.
Optionally we can add a "no_shadow" to the cloud layer.

// sky -----------------------------------
sky_sphere{
 pigment{ gradient y
   color_map{
   [0.0 color rgb<1,1,1> ]
   [0.3 color rgb<0.18,0.28,0.75>*0.8]
   [1.0 color rgb<0.15,0.28,0.75>*0.5]}
   scale 1.05
   translate<0,-0.05,0>
 } // end pigment
} // end sky_sphere

// spherical cloud layer ----------------
#declare R_planet = 6000000;
#declare R_sky    = R_planet + 2000;
sphere{ <0, -R_planet, 0>, R_sky hollow
  texture{
     pigment{ bozo turbulence 0.75
              octaves 6  omega 0.7
              lambda 2  phase 0.15
         color_map {
         [0.00 color rgb <1,1,1>*0.95]
         [0.05 color rgb <1,1,1>*1.25]
         [0.15 color rgb <1,1,1>*0.85]
         [0.55 color rgbt<1,1,1,1>]
         [1.00 color rgbt<1,1,1,1>]
       } // end color_map
       translate< 3, 0,-1>
       scale<0.3, 0.4, 0.2>*3
     } // end pigment
     #if(version = 3.7)
           finish{emission 1 diffuse 0}
     #else finish{ ambient 1 diffuse 0}
     #end
     scale 3000
  } // end texture
   // no_shadow // optional!!
 } // end of sphere ---------------------

Sky with clouds with phase 0.00 to 0.15.
Description of this scenery for POV-Ray

Sky with clouds casting shadows on the ground.

Sky with clouds view from above.
Note: the "cloud layer" does not have any thickness!

Overview | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10

Descriptions and Examples for the POV-Ray raytracer
by Friedrich A. Lohmüller