Comment créer un ciel réaliste avec POV-Ray

Nuages avec l'ombre sur le sol :

Pour obtenir cet effet le solei doit être positionné au-dessous du plan plus 'haut avec la couleur bleu et sur le plan transparent avec les nuages blancs.
Pour faciliter de trouver une position du solei précisement entre les nuages on peut utiliser une sphère avec un texture miroitant et avec phong par ex. "Polished_Chrome".

Nuages avec l'ombre sur le sol.
Cliquez sur l'image pour une résolution plus 'haut!
Description de cette scène pour POV-Ray

Nuages avec l'ombre sur le sol.
Une solution du problèm de l'horizon sans "fog".
Here we split the sky into two parts:
1: Une sky_sphere avec le couleur de blanc à bleu.
2: Une sphère gigantique avec un motif transparent avec nuages. En raison du grand rayon il apparaît presque comme un plan et les nuages deviennent plus petits près de l'horizon.
Avec cette solution, nous n'avons pas besoin de garder le light_source pour notre soleil en dessous du niveau des nuages. Mais nous devons déplacer le soleil ou les nuages si l'ombre des nuages frappe parties de notre scène qui nous voulons être en plein soleil.
En option, nous pouvons ajouter un "no_shadow" à la couche de nuages.

// sky -----------------------------------
sky_sphere{
 pigment{ gradient y
   color_map{
   [0.0 color rgb<1,1,1> ]
   [0.3 color rgb<0.18,0.28,0.75>*0.8]
   [1.0 color rgb<0.15,0.28,0.75>*0.5]}
   scale 1.05
   translate<0,-0.05,0>
 } // end pigment
} // end sky_sphere

// spherical cloud layer ----------------
#declare R_planet = 6000000;
#declare R_sky    = R_planet + 2000;
sphere{ <0, -R_planet, 0>, R_sky hollow
  texture{
     pigment{ bozo turbulence 0.75
              octaves 6  omega 0.7
              lambda 2  phase 0.15
         color_map {
         [0.00 color rgb <1,1,1>*0.95]
         [0.05 color rgb <1,1,1>*1.25]
         [0.15 color rgb <1,1,1>*0.85]
         [0.55 color rgbt<1,1,1,1>]
         [1.00 color rgbt<1,1,1,1>]
       } // end color_map
       translate< 3, 0,-1>
       scale<0.3, 0.4, 0.2>*3
     } // end pigment
     #if(version = 3.7)
           finish{emission 1 diffuse 0}
     #else finish{ ambient 1 diffuse 0}
     #end
     scale 3000
  } // end texture
   // no_shadow // optional!!
 } // end of sphere ---------------------

Ciel avec nuages et phase 0.00 à 0.15.
Description de cette scène pour POV-Ray

Ciel avec des nuages ombres de coulée sur le terrain.

Ciel avec les nuages vue d'en haut.
Note: la «couche de nuages» n'a pas épaisseur!

Contenu | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10

Descriptions et Exemples pour le raytracer de POV-Ray par Friedrich A. Lohmüller,

Nuages avec l'ombre sur le sol :

Nuages avec l'ombre sur le sol. Cliquez sur l'image pour une résolution plus 'haut! Description de cette scène pour POV-Ray

Nuages avec l'ombre sur le sol.
Cliquez sur l'image pour une résolution plus 'haut!
Description de cette scène pour POV-Ray