Realistische Himmel mit POV-Ray

Schatten werfende Wolken:

Um diesen Effekt zu erhalten muss die Sonne zwischen der höchsten teilweise transparenten Wolkenschicht und der Ebene mit dem Himmelsblau plaziert werden.
Um eine genaue Positionierung der Sonne in einer Wolkenlücke zu erleichtern, kann man eine spiegelnde Kugel mit einem Phong-Glanzlicht (damit die Sonnenposition sichtbar wird!) verwenden. z.B. ein Kugel mit "Polished_Chrome"-Texture.

Wolken, die auf dem Untergrund Schatten werfen.
Für größere Auflösung auf Bild klicken!
Szenenbeschreibung für POV-Ray

Schatten werfende Wolken
Eine Lösung des Horizont-Problems ohne "fog".
Hierzu teilen wir den Himmel in 2 Teile auf:
1: Eine sky_sphere mit Farbübergang von Weiß zu Blau.
2: Eine riesige Kugel mit einem transparenten Wolkenmuster. Wegen des großen Radius erschein diese nahezu als eine Ebene und die Wolken werden zum Horizont hin kleiner.
Mit dieser Lösung müssen wir die light_source für unsere Sonne jetzt nicht mehr unter dem Wolkenlevel halten. Aber wir müssen die Sonne oder die Wolken verschieben, sollen die Wolkenschatten Bereiche unserer Szene treffen, die wir voll im Sonnenlicht haben wollen.
Optional läßt sich ein "no_shadow" der Wolkenschicht hinzufügen.

// sky -----------------------------------
sky_sphere{
 pigment{ gradient y
   color_map{
   [0.0 color rgb<1,1,1> ]
   [0.3 color rgb<0.18,0.28,0.75>*0.8]
   [1.0 color rgb<0.15,0.28,0.75>*0.5]}
   scale 1.05
   translate<0,-0.05,0>
 } // end pigment
} // end sky_sphere

// spherical cloud layer ----------------
#declare R_planet = 6000000;
#declare R_sky    = R_planet + 2000;
sphere{ <0, -R_planet, 0>, R_sky hollow
  texture{
     pigment{ bozo turbulence 0.75
              octaves 6  omega 0.7
              lambda 2  phase 0.15
         color_map {
         [0.00 color rgb <1,1,1>*0.95]
         [0.05 color rgb <1,1,1>*1.25]
         [0.15 color rgb <1,1,1>*0.85]
         [0.55 color rgbt<1,1,1,1>]
         [1.00 color rgbt<1,1,1,1>]
       } // end color_map
       translate< 3, 0,-1>
       scale<0.3, 0.4, 0.2>*3
     } // end pigment
     #if(version = 3.7)
           finish{emission 1 diffuse 0}
     #else finish{ ambient 1 diffuse 0}
     #end
     scale 3000
  } // end texture
   // no_shadow // optional!!
 } // end of sphere ---------------------

Wolkenhimmel mit phase 0.00 bis 0.15.
Szenenbeschreibung für POV-Ray

Wolken, die Schatten werfen.

Die Wolken von oberhalb.
Anmerkung: Die "Wolkenschicht" besitzt keinerlei Dicke!

Inhalt | 1 | 2 | 3 | 4 | 5 | 6 | 7.0 | 7.1 | 8 | 9 | 10

Beschreibungen und Beispiele zum Raytracer POV-Ray von Friedrich A. Lohmüller