Cette forme est définie dans mon
include file "shapes3.inc"
( anciennement "shapes_lo.inc" ) .
Egg - Oeuf
|
Egg_Shape - forme d'oeuf
|
syntaxe générale :
object{ Egg
texture{ ... }
scale 1
rotate <0,0,0>
translate < 0, 0, 0>
} // end of object ---- |
|
syntaxe générale :
object{ Egg_Shape( Lower_Scale,
Upper_Scale
) //----------
texture{ ... ... }
} // end of object ------ |
Lower_Scale =
y échelle de la moitié inférieure de la forme,
Upper_Scale =
y échelle de la moitié supérieure de la forme.
La hauteur totale de ces formes est à l'échelle de 2 unités.
|
Exemple :
#include "shapes3.inc"
object{ Egg // = Egg_Shape(1.15,1.55)
texture{
pigment{ color rgb<1,1,1>}
normal { bumps 0.5 scale .002}
finish { phong 0.5 }
} // end of texture
rotate < 0, 0, 0>
translate < 0, 0, 0>
} // end of object -------------------- |
|
Exemple :
#include "shapes3.inc"
object{ Egg_Shape( 2.05, 0.65 )
texture{
pigment{ color rgb<1,1,1>}
normal { bumps 0.5 scale .002}
finish { phong 1 }
} // end of texture
rotate < 0, 0, 0>
translate < 0, 0, 0>
} // end of object --------------------- |
|
Voici quelques variations de cette macro :
|
|
|
| "Egg object"
|
"Egg object"
|
La macro en détail
Cette macro est réalisée par une union avec deux 2 intersections d'éllipse
avec les boites appropriées :
// -------------------------------------- macro Egg_Shape (...)
#macro Egg_Shape (Lower_Scale, Upper_Scale) //
// ------------------------------------------------------------
#local Egg_Lower_Part =
difference {
sphere{<0,0,0>,1 scale<1,Lower_Scale,1>}
box{<-1,0,-1>,<1,Lower_Scale,1>}
} //---------------------------------------
#local Egg_Upper_Part =
difference {
sphere {<0,0,0>,1 scale<1,Upper_Scale,1>}
box {<-1,-Upper_Scale,-1>,<1,0,1>}
}//---------------------------------------
//-------------------------------------------------------------
union {
object {Egg_Upper_Part}
object {Egg_Lower_Part}
translate<0,Lower_Scale,0>
scale 2/(Lower_Scale+Upper_Scale)
} // end of union -------------------------------------
#end //---------------------------------- end of the egg macro |
L'objet "Egg" est réalisée avec la même macro :
// ---------------------------- shape of a simple egg
#declare Egg = object { Egg_Shape (1.15,1.55)}
// ------------------------------------- end of the egg object |
|
|
