Un Corps d'une Guitare

Objets :  prism.
Méthodes : cubic_spline.

La construction d'un corps d'une guitare en détail :
Nous pouvons faire la forme de base du corps par un prism (généralisé aussi avec une ligne courbe sur la base de surface!) si nous prenons une curve "cubic spline" pour la surface convexe latérale.
Pour la définition d'un prism approprié nous avons besoin d'une file de points de base pour modeler le tracé d'un corps d'une guitare.
Le placement de ces points de base est une affaire très sensible - cest-à-dire : nous devons appliquer la méthode de "trial and error".
Si nous placons ces points dans le plan xy, la forme du corps est symétrique au plan yz. La manière plus facile pour définer les points symétrique au plan yz est la déclaration comme variables.

// ----------- Dimensions
#declare G_z = 0.15;// -z value
// Silhuette right side:
// ----  values -----
#local S0 = < 0.00, 0.00>;
#local S1 = < 0.16, 0.05>;
#local S2 = < 0.22, 0.20>;
#local S3 = < 0.15, 0.35>;
#local S4 = < 0.17, 0.48>;
#local S5 = < 0.12, 0.56>;
#local S6 = < 0.00, 0.60>;
// vectors of 2 dim. S(u,v).
// If S= S(Xs,Yx),
// then S.u=Xs u. X.v=Ys.

// automatic mirror image
// Silhuette left side:
#local S7 = <-S5.u, S5.v>;
#local S8 = <-S4.u, S4.v>;
#local S9 = <-S3.u, S3.v>;
#local S10 = <-S2.u, S2.v>;
#local S11 = <-S1.u, S1.v>;
//--------------------------
// linear prism in y direction:
prism {
   linear_sweep
   cubic_spline
   G_z, 0.00, 15

   S0, S1, S2, S3, S4,
   S5, S6, S7, S8, S9,
   S10, S11,
   S0, // last = first
   S1, // 2 more !!!
   S2
   texture { /*as you like it!*/}
   rotate<-90,0,0>
   //roatates the prism in in plane xy!!!
   translate<0.0,0,0>
} // end of prism ------------

Le corps d'une Guitare:
Les points de base du tracé sont marqués par des sphères petits. Les points de S7 à S11 en positions symétriques sont marqués en vert.

Cliquez ici pour le fichier du scène complet
pour POV-Ray:
"guitar.txt" ou "guitar.pov"

Si nous definissons ce prism comme un objet "Body_Shape" nous pouvons modeler le corps d'une guitare avec cette forme di base.
Pour obtenir des textures differentes sur le devant et le derrière et les côtés, nous pouvons changer l'échelle de la forme de base et assembler tous par "union". Après cela nous devons soustraire un forme di base avec l'échelle réduit et un cylindre pour creuser l'intérieur et pour obtenir le trou dans le corps de la guitare.

Cela veut montrer l'exemple suivant :

//-------- The Guitar_Body
difference{
union { //the positiv parts
 object{Body_Shape
  scale< 1.010,1.010,  0.95>
  translate<0,-0.005*G_y, -0.05*G_z/2>
  texture{G_Texture_outside1} }
 object{Body_Shape
  texture{G_Texture_outside  } }
}// end of the union of
 //the positiv parts of the body

// caving out the inside
object{Body_Shape
  scale<0.99,0.99,1-0.01*(1/G_z)>
  translate<0,0.005,-0.005>
  texture{G_Texture_inside}}
// the hole - das Loch
cylinder{<0,0,-0.1>,<0,0,0.1>,G_Hole_R
  translate<0,G_Hole_y,-G_z>
  texture{G_Texture_outside}
  } // end of cylinder  ----------
}// end of difference  -----------
// ------------ end of Guitar_Body

La description de la scène pour POV-Ray:
"guitar.txt" ou "guitar.pov"