Page d'Accueil
- POV-Ray Tutorial
- Exemples POV-Ray
Table des matières
- Architecture
- Geometrie
- Technique
- Échelle
- Pylônes
- Garde-fou, Rambarde
- Pont
- Tuyaux
- Bifurcation de Tuyau
- Robinet d'Arrêt
- Chaîne
- Bobine de fil
- Torpedo
- Cruise Missile
- Missile
- Roue
- Camion
- Hélice
- Avion
- Canoë
- Guitare
- Afficheur 7 segments
- Câble plat - Nappe plat
- Harnais de câbles
|
|
|
Canoë
La construction d'un canoë
et le positionnement dans l'eau
avec "transform{...}"
Objets: sphere, box.
Méthodes: #declare, union, intersection, inverse, transform.
|
|
 |
 |
| La silhouette est un ellipsoide - il est né un canoë ! |
|
|
Le contour d'un ellipsoide forme la face externe d'un canoë.
Cette forme est creusée par une version d'échelle plus petite de soi-même.
("intersection" avec l'"inverse")
De cette forme on doit découper un ellipsoide :
#declare Canoe_outside=
sphere {<0,0,0>,1 scale <3,1.5,1> translate<0,0.5,0> }
//-----------------------------------------------------
#declare Canoe =
intersection{
object{ Canoe_outside }
object{ Canoe_outside scale <0.98,0.95,0.94> inverse}
sphere {<0,0,0>,1 scale <2.5,1,20> translate<0,1.3,0> inverse}
texture{pigment{color White*1.1}
finish {ambient 0.45 diffuse 0.55 phong 1}}
} // end of outside structure of the canoe ------------------- |
Naturellement nous devons permettre quelques places assises
à l'intérieur du canoë !
Si nous mettons purement le canoë sur la surface de l'eau
l'usager sera mouillé - mais non seulement de larmes !
|
 |
Pour éviter cela nous devons soustraire
la forme extérieur canoë
de la surface de l'eau
exactement à la position de notre canoë.
|
 |
| À cette manière un canoë est une joie sans mélange !
|
 |
Pour faciliter le placement du trou dans l'eau à la même position comme le canoë,
il est indiqué de définir la position et c'est possible aussi quelconques rotations dans une transformation :
#declare Canoe_Position1
= transform{ rotate < 0,30, 0> translate<0,0,1>} |
Cette transformation puis on peut utiliser pour le canoë et aussi pour le trou (Canoe_outside) dans la surface de l'eau :
//-------------------------------------< place canoe
object{ Canoe transform Canoe_Position1}
// -----------------------------------< hole in the water
difference{
plane{<0,1,0>, 0 } // the water
object{Canoe_outside
transform Canoe_Position1 } // the hole
texture{Polished_Chrome
normal {crackle 1 scale 5
turbulence 1 translate<0,0,5>}
finish {diffuse 0.5
reflection 0.4}}
}// end of difference
//---------------------------------------------------- end |
La efficacité véritable de cette méthode entre en jeu naturellement seulement si nous
pouvons payer pour plus que un seule canoë !-)
Le fichier de cette scène pour POV-Ray :
"canoe.txt"
|
|
